Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Solve stuck at 243

• To: mathgroup at smc.vnet.net
• Subject: [mg124220] Re: Solve stuck at 243
• From: DrMajorBob <btreat1 at austin.rr.com>
• Date: Sat, 14 Jan 2012 02:54:30 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• References: <201201130953.EAA16531@smc.vnet.net>
• Reply-to: drmajorbob at yahoo.com

I believe there are two such numbers less than 500,000:

limit = 500000;
Timing[can =
   Union@First@
     Last@Reap@
       Do[Sow[Prime@m + 2 k^2], {m, 2, PrimePi@limit}, {k, 1, Sqrt[(
         limit - Prime@m)/2]}];
  cannot =
   Complement[Range[3, limit, 2], Prime@Range@PrimePi@limit, can]]

{44.8573, {5777, 5993}}

That makes 5777 the smallest.

This also works, but it may be slower:

limit = 500000;
Timing[can =
   Union@Flatten@
     Table[Prime@m + 2 k^2, {m, 2, PrimePi@limit}, {k, 1, Sqrt[(
       limit - Prime@m)/2]}];
  cannot =
   Complement[Range[3, limit, 2], Prime@Range@PrimePi@limit, can]]

{48.9388, {5777, 5993}}

Best of all is knowing how far to look:

limit = 6000;
Timing[can =
   Union@First@
     Last@Reap@
       Do[Sow[Prime@m + 2 k^2], {m, 2, PrimePi@limit}, {k, 1, Sqrt[(
         limit - Prime@m)/2]}];
  cannot =
   Complement[Range[3, limit, 2], Prime@Range@PrimePi@limit, can]]

{0.187722, {5777, 5993}}

Bobby

On Fri, 13 Jan 2012 03:53:15 -0600, Ralph Dratman  
<ralph.dratman at gmail.com> wrote:

> Project Euclid asks, "What is the smallest odd composite
> that cannot be written as the sum of a prime and twice a
> square?"
>
> I tried the following equation, not really expecting it to
> work:
>
> oddComposite == Prime[m] + 2 k^2
>
> Surprisingly, the above actually does work for all the odd
> composite numbers through 237.
>
> solveInstance[oddComposite_] := Solve[{oddComposite ==
> Prime[m] + 2*k^2, k > 0, m > 0}, {k, m}, Integers];
> For[i = 9, i < 300, i = i + 2,
> If[Not[PrimeQ[i]], Print[i,": ", solveInstance[i]]]]
>
> 9: {{k->1,m->4}}
> 15: {{k->1,m->6},{k->2,m->4}}
> 21: {{k->1,m->8},{k->2,m->6},{k->3,m->2}}
> 25: {{k->1,m->9},{k->2,m->7},{k->3,m->4}}
> 27: {{k->2,m->8}}
> 33: {{k->1,m->11}}
> 35: {{k->3,m->7},{k->4,m->2}}
> 39: {{k->1,m->12},{k->2,m->11},{k->4,m->4}}
> 45: {{k->1,m->14},{k->2,m->12},{k->4,m->6}}
> 49: {{k->1,m->15},{k->2,m->13},{k->3,m->11},{k->4,m->7}}
> 51: {{k->2,m->14},{k->4,m->8}}
>
> - - - - - - snip - - - - - -
>
> 217: {{k->3,m->46},{k->5,m->39},{k->8,m->24},{k->10,m->7}}
> 219: {{k->2,m->47},{k->10,m->8}}
> 221: {{k->6,m->35},{k->9,m->17}}
> 225: {{k->1,m->48},{k->4,m->44},{k->7,m->31},{k->8,m->25}}
> 231:
> {{k->1,m->50},{k->2,m->48},{k->4,m->46},{k->5,m->42},{k->8,m
> ->27},{k->10,m->11}}
> 235:
> {{k->1,m->51},{k->2,m->49},{k->6,m->38},{k->7,m->33},{k->8,m
> ->28},{k->9,m->21}}
> 237: {{k->2,m->50},{k->7,m->34},{k->8,m->29},{k->10,m->12}}
>
> - - - - - - but then, at 243, something changes - - - - -
>
> 243: {{k->1,m->53},{k->4,m->47},{k->5,m->44},{k->10,m->14}}
> Solve::nsmet: This system cannot be solved with the methods
> available to Solve. >>
>
> 245: Solve[{245==2 k^2+Prime[m],k>0,m>0},{k,m},Integers]
> Solve::nsmet: This system cannot be solved with the methods
> available to Solve. >>
>
> 247: Solve[{247==2 k^2+Prime[m],k>0,m>0},{k,m},Integers]
> Solve::nsmet: This system cannot be solved with the methods
> available to Solve. >>
>
> ... and so on. Strange.
>
> Does anyone know why such a threshold might appear?
>
> Thank you.
>
> Ralph Dratman
>


-- 
DrMajorBob at yahoo.com

• References:
  • Solve stuck at 243
    • From: Ralph Dratman <ralph.dratman@gmail.com>