Re: Flattening a hypermatrix into an ordinary matrix
- To: mathgroup at smc.vnet.net
- Subject: [mg126731] Re: Flattening a hypermatrix into an ordinary matrix
- From: "Oleksandr Rasputinov" <oleksandr_rasputinov at ymail.com>
- Date: Sat, 2 Jun 2012 05:47:42 -0400 (EDT)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- References: <jqa1j4$bjd$1@smc.vnet.net>
On Fri, 01 Jun 2012 10:21:40 +0100, <carlos at colorado.edu> wrote:
> I have an n x n hypermatrix, the entries of which are m x m blocks.
> For example A below (m=3, n=2):
>
> A11={{B11,B12,B13},{B21,B22,B23},{B31,B32,B33}};
> A12={{C11,C12,C13},{C21,C22,C23},{C31,C32,C33}};
> A21={{D11,D12,D13},{D21,D22,D23},{D31,D32,D33}};
> A22={{E11,E12,E13},{E21,E22,E23},{E31,E32,E33}};
> A={{ A11,A12},{A21,A22}};
>
> I want to convert this to an ordinary n*m x n*m matrix.
> For the example I want A to become
>
> {{B11,B12,B13,C11,C12,C13},{B21,B22,B23,C21,C22,C23},
> {B31,B32,B33,C31,C32,C33},{D11,D12,D13,E11,E12,E13},
> {D21,D22,D23,E21,E22,E23},{D31,D32,D33,E31,E32,E33}}
>
> This can be easily done with C style loops as
>
> AA=Table[0,{m*n},{m*n}];
> For [i=1,i<=n,i++, For[j=1,j<=n,j++,
> For [k=1,k<=m,k++, For [l=1,l<=m,l++,
> AA[[m*(i-1)+k,m*(j-1)+l]]=A[[i,j,k,l]]
> ]]]];
>
> but is there a more elegant way using Flatten?
> (Flatten[A,1] doesnt do it.) It should work also for blocks
> of varying size for future use.
>
Yes; you can use:
Flatten[A, {{1, 3}, {2, 4}}]
{{B11, B12, B13, C11, C12, C13}, {B21, B22, B23, C21, C22, C23},
{B31, B32, B33, C31, C32, C33}, {D11, D12, D13, E11, E12, E13},
{D21, D22, D23, E21, E22, E23}, {D31, D32, D33, E31, E32, E33}}
which flattens together levels 1 and 3 to form level 1 in the result, and
levels 2 and 4 to form level 2. (I often find it helpful to look at
Dimensions[A], which is {2, 2, 3, 3}, to figure out what is needed in
cases like this.)
Since the Flatten documentation is rather terse, for a more detailed
description of how this works, I'd suggest having a look at Leonid
Shifrin's answer at:
http://mathematica.stackexchange.com/questions/119/flatten-command-matrix-as-second-argument