Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Moment function

  • To: mathgroup at smc.vnet.net
  • Subject: [mg126978] Re: Moment function
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Thu, 21 Jun 2012 05:20:54 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • References: <201206200748.DAA04927@smc.vnet.net>

dist = NormalDistribution[m, s];

assume = {Element[m, Reals], Element[{n, p}, Integers], s > 0, n >= 0, p>= 0};

moment1 = Moment[dist, n*p]

moment2 = Assuming[assume, Integrate[z^(n*p)*PDF[dist, z], {z, -Infinity, Infinity}]//Simplify]

distp = TransformedDistribution[z^p, z \[Distributed] dist];

moment3 = Assuming[assume, FullSimplify[Moment[distp, n]]]

Assuming[assume, FullSimplify[moment2 == moment3]]

True

{moment1, moment2, moment3} /. {n -> 1, p -> 1}

{m, m, m}

And@@Flatten[Table[Assuming[assume, Simplify[moment1 == moment2 == moment3]], {n, 0, 5}, {p, 0, 5}]]

True

The first method is very much faster.


Bob Hanlon


On Jun 20, 2012, at 3:48 AM, paul <paulvonhippel at yahoo.com> wrote:

> I would like a formula for the mth moment of Z^p, where Z~Normal(mu,sigma) and p is a positive integer. With m=p=1, the answer should be mu -- i.e., the first moment of a normal variable is the mean mu. But that's not what I get when I do it this way:
>
> momentPN =
> FullSimplify[
>  Moment[TransformedDistribution[Z^p,
>    Z \[Distributed] NormalDistribution[\[Mu], \[Sigma]]], m], {m > 0,
>    p > 0, Element[p, Integers], Element[m, Integers]}]
>
> FullSimplify[
> momentPN /. {p -> 1, m -> 1}, {\[Sigma] > 0, Element[\[Mu], Reals]}]
>
> I know other ways to get the right answer, but why doesn't this method work?
>



  • Prev by Date: multiplying, element wise, a row by each column of a matrix.
  • Next by Date: Re: NDSolve profiling
  • Previous by thread: Moment function
  • Next by thread: NDSolve profiling