MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: plot of function of two variables


$Version

"7.0 for Mac OS X x86 (64-bit) (November 11, 2008)"

Manipulate[
 ContourPlot[(x - a)^2 + (y - b)^2 == r^2,
  {x, a - r, a + r},
  {y, b - r, b + r},
  Frame -> False,
  Axes -> True,
  AxesLabel -> {"x", "y"},
  PlotRange ->
   {{-15.5, 15.5}, {-15.5, 15.5}}],
 {{a, 0}, -5, 5, 1, Appearance -> "Labeled"},
 {{b, 0}, -5, 5, 1, Appearance -> "Labeled"},
 {{r, 5, "|r|"}, 1, 10, 1,
  Appearance -> "Labeled"}]

Manipulate[
 Plot[Evaluate[y /.
    Solve[(x - a)^2 + (y - b)^2 == r^2, y]],
  {x, a - r, a + r},
  AspectRatio -> 1,
  FrameLabel -> {"x", "y"},
  PlotRange ->
   {{-15.5, 15.5}, {-15.5, 15.5}}],
 {{a, 0}, -5, 5, 1, Appearance -> "Labeled"},
 {{b, 0}, -5, 5, 1, Appearance -> "Labeled"},
 {{r, 5, "|r|"}, 1, 10, 1,
  Appearance -> "Labeled"}]


Bob Hanlon


On Sat, Oct 13, 2012 at 1:03 AM, Miguel Aragon <aragon.miguel at gmail.com> wrote:
>
> I have a question about how to plot a function of two variable of the form
> (x-a)^2 + (y-b)^2 = r^2 with Mathematica v 7.0?  Is it possible?
>
> Thank you,
>
> --
> Miguel Aragon
> aragon.miguel at gmail.com
>
>



  • Prev by Date: Solve
  • Next by Date: Re: plot function of two variables
  • Previous by thread: Re: plot a function of two variables
  • Next by thread: Re: plot of a function of two variables