Re: Solve

• To: mathgroup at smc.vnet.net
• Subject: [mg128423] Re: Solve
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Sun, 14 Oct 2012 23:42:01 -0400 (EDT)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-newout@smc.vnet.net
• Delivered-to: mathgroup-newsend@smc.vnet.net

```g[\[Alpha]_] := \[Rho] (\[Delta] - \[Alpha] \[Delta] + \[Rho] + \[Alpha] \
\[Rho] - 2 Sqrt[\[Alpha] \[Rho] (\[Delta] - \[Alpha] \[Delta] + \[Rho])])

sol1 = Solve[g'[\[Alpha]] == 0, \[Alpha], Reals]

{{\[Alpha] -> ConditionalExpression[1, \[Rho] > 0]},
{\[Alpha] -> ConditionalExpression[\[Rho]/\[Delta], \[Rho] < 0]}}

Solve[{g'[\[Alpha]] == 0, \[Rho] > 0}, \[Alpha], Reals] //
Simplify[#, \[Rho] > 0] &

{{\[Alpha] -> 1}}

g'[1] // Simplify[#, \[Rho] > 0] &

0

Solve[{g'[\[Alpha]] == 0, \[Rho] < 0}, \[Alpha], Reals] //
Simplify[#, \[Rho] < 0] &

{{\[Alpha] -> \[Rho]/\[Delta]}}

g'[\[Rho]/\[Delta]] // Simplify[#, \[Rho] < 0] &

0

"Solve deals primarily with linear and polynomial equations. " Use Reduce

sol2 = Reduce[g'[\[Alpha]] == 0, \[Alpha], Reals] // Simplify

(\[Rho] < 0 && ((\[Alpha] == \[Rho]/\[Delta] && (\[Delta] < 0 ||
\[Delta] + \[Rho] >
0 || (\[Delta] > 0 && \[Delta] + \[Rho] < 0))) ||
(\[Alpha] < 0 && \[Delta] + \[Rho] == 0))) ||
(\[Rho] > 0 && (\[Alpha] == 1 || (\[Alpha] > 0 &&
\[Delta] + \[Rho] == 0))) || (\[Delta] != 0 && \[Rho] == 0 &&
(\[Alpha] > 1 || \[Alpha] < 0 || 0 < \[Alpha] < 1))

Simplify[sol2, \[Rho] > 0]

\[Alpha] == 1 || (\[Alpha] > 0 && \[Delta] + \[Rho] == 0)

Simplify[g'[1], \[Rho] > 0]

0

Simplify[g'[\[Alpha]], {\[Rho] > 0, \[Alpha] > 0, \[Delta] + \[Rho] == 0}]

0

Simplify[sol2, \[Rho] < 0]

(\[Alpha] == \[Rho]/\[Delta] && (\[Delta] < 0 || \[Delta] + \[Rho] >
0 || (\[Delta] > 0 && \[Delta] + \[Rho] < 0))) || (\[Alpha] <
0 && \[Delta] + \[Rho] == 0)

Simplify[g'[\[Alpha]], {\[Rho] < 0, \[Alpha] == \[Rho]/\[Delta], \[Delta] <
0}]

0

Simplify[g'[\[Alpha]], {\[Rho] <
0, \[Alpha] == \[Rho]/\[Delta], \[Delta] + \[Rho] > 0}]

0

Simplify[g'[\[Alpha]], {\[Rho] < 0, \[Alpha] == \[Rho]/\[Delta], \[Delta] >
0, \[Delta] + \[Rho] < 0}]

0

Simplify[g'[\[Alpha]], {\[Rho] < 0, \[Alpha] < 0, \[Delta] + \[Rho] == 0}]

0

Bob Hanlon

On Sun, Oct 14, 2012 at 12:13 AM,  <JikaiRF at aol.com> wrote:
> Dear members:
> I basecally intend to solve the following equation for \[Alpha]:
>
> g[\[Alpha]_]:=\[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho]+\[Alpha] \[Rho]-2 Sqrt[\[Alpha] \[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho])])
>
> First of all, in order to investigate the function g, I differentiate g(\[Alpha]) with \[Alpha]. I input the following formula into Mathematica.
>
> D[g[\[Alpha]],\[Alpha]].
>
> As a result, I obtain
>
>  g'(\[Alpha])=\[Rho] (-\[Delta]+\[Rho]-(-\[Alpha] \[Delta] \[Rho]+\[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho]))/Sqrt[\[Alpha] \[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho])]).
>
> At this stage, I input the following to find \[Alpha] satisfying g'(\[Alpha])=0.
>
> Solve[\[Rho] (-\[Delta]+\[Rho]-(\[Rho] (\[Delta]-2 \[Alpha] \[Delta]+\[Rho]))/Sqrt[\[Alpha] \[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho])])==0, \[Alpha]],
>
> then I obtain the following  from Mathematica:
>
> {{\[Alpha]->1},{\[Alpha]->\[Rho]/\[Delta]}}.
>
> However, g'(\[Rho]/\[Delta]) = \[Rho] (-\[Delta]+\[Rho]-((\[Delta]-\[Rho]) \[Rho])/Sqrt[\[Rho]^2]) = 2(\[Rho] - \[Delta])  holds, if \[Rho] > 0. On the other hand, if \[Rho] < 0, g'(\[Rho]/\[Delta]) = 0 holds.
>
> This diferrence is derived from the fact that the Solve interpreates Sqrt[\[Rho]^2] = - \[Rho].
> But the value I sassume is \[Rho] > 0.
> In order to make sure, I define a new function, which is equals to g'(\[Alpha]), as
>
> y[\[Alpha]_]:=\[Rho] (-\[Delta]+\[Rho]-(\[Rho] (\[Delta]-2 \[Alpha] \[Delta]+\[Rho]))/Sqrt[\[Alpha] \[Rho] (\[Delta]-\[Alpha] \[Delta]+\[Rho])])
>
> And when I put \[Alpha] = \[Rho]/\[Delta] into y, I obtain \[Rho] (-\[Delta]+\[Rho]-((\[Delta]-\[Rho]) \[Rho])/Sqrt[\[Rho]^2]).
> In my opinion, the Solve function is programmed to override alternative solutions. In other words, it is overdetermined in an unfortunate way. In this case, Sqrt[\[Rho]^2]) is interpreted as \[Rho] < 0.
>
> Is this correct?
>
>         Fujio Takata
>         Kobe University, Japan.
>

```

• References:
• Solve
• From: JikaiRF@aol.com
• Prev by Date: Re: sum of coins article in mathematica journal
• Next by Date: Re: How to simplify hypergeometrics