Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: ParametricLinePlot3D

• To: mathgroup at smc.vnet.net
• Subject: [mg131970] Re: ParametricLinePlot3D
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Thu, 7 Nov 2013 00:28:16 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-outx@smc.vnet.net
• Delivered-to: mathgroup-newsendx@smc.vnet.net
• References: <20131106053523.B859D6A45@smc.vnet.net>

Your example works for an initial evaluation since v is undefined when
Ringsweep1 is defined. However, for subsequent evaluations the last value
of v carries over and Ringsweep1 is defined with that value of v. Hence
subsequent changes in v are not reflected in Ringsweep1. Just clear v prior
to defining Ringsweep1.


Clear[v];


R = 2.; a = 1.;


Ringsweep1[u_] = {
   a Cos[R Sin[u]/a] Cos[v] - Sin[v]*a Sin[R Sin[u]/a],
   a Cos[R Sin[u]/a] Sin[v] + Cos[v]*a Sin[R Sin[u]/a],
   R Cos[u]};


v = Pi/3;


g1 = ParametricPlot3D[
   Tooltip[Ringsweep1[u], StringForm["v = ``", v]],
   {u, 0, 2 Pi},
   PlotStyle -> {Red, Thick}];


v = 2 Pi/3;


g2 = ParametricPlot3D[
   Tooltip[Ringsweep1[u], StringForm["v = ``", v]],
   {u, 0, 2 Pi},
   PlotStyle -> {Blue, Thick}];


v = 4 Pi/3;


g3 = ParametricPlot3D[
   Tooltip[Ringsweep1[u], StringForm["v = ``", v]],
   {u, 0, 2 Pi},
   PlotStyle -> {Green, Thick}];


Show[{g1, g2, g3}, PlotRange -> All]


This can be shortened to


ParametricPlot3D[
 Evaluate[Table[
   Tooltip[Ringsweep1[u], StringForm["v = ``", v]],
   {v, {Pi/3, 2 Pi/3, 4 Pi/3}}]],
 {u, 0, 2 Pi},
 PlotStyle -> ({Thick, #} & /@ {Red, Blue, Green})]



Bob Hanlon




On Wed, Nov 6, 2013 at 12:35 AM, Narasimham <mathma18 at gmail.com> wrote:

> Or least, why should the v new parameter values be ignored in subsequent
> settings when the function is solely dependent on u only?
>
> R = 2.; a = 1.;
> Ringsweep1[u_] = {a Cos[R Sin[u]/a] Cos[v] - Sin[v]*a Sin[R Sin[u]/a],
>     a Cos[R Sin[u]/a] Sin[v] + Cos[v]*a Sin[R Sin[u]/a], R Cos[u]};
> v = Pi/3;
> g1 = ParametricPlot3D[Ringsweep1[u], {u, 0, 2 Pi},
>   PlotStyle -> {Red, Thick}]
> v = 2 Pi/3;
> g2 = ParametricPlot3D[Ringsweep1[u], {u, 0, 2 Pi},
>   PlotStyle -> {Red, Thick}]
> v = 4 Pi/3;
> g3 = ParametricPlot3D[Ringsweep1[u], {u, 0, 2 Pi},
>   PlotStyle -> {Red, Thick}]
> Show[{g1, g2, g3}, PlotRange -> All]
>
> Under such circumstances, why Manipulating by varying v is not possible
> inside its Box?
>
> Regards
> Narasimham
>
>

• References:
  • Re: ParametricLinePlot3D
    • From: Narasimham <mathma18@gmail.com>