Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2013

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Animate cannot be combined?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg132030] Re: Animate cannot be combined?
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Tue, 19 Nov 2013 02:58:15 -0500 (EST)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-outx@smc.vnet.net
  • Delivered-to: mathgroup-newsendx@smc.vnet.net
  • References: <20131117232255.BFA716A26@smc.vnet.net>

Animate[
 Module[{h = 0.5, dt = 0.8,
   HypPar, EndCircs},
  HypPar[u_] = Line[{
     {Cos[u], Sin[u], 0},
     {Cos[u + dt], Sin[u + dt], h}}];
  EndCircs = ParametricPlot3D[{
     {Cos[v + 1.5], Sin[v + 1.5], 0},
     {Cos[v], Sin[v], h}},
    {v, 0, 2 Pi}];
  Show[
   EndCircs,
   Graphics3D[{Thick, HypPar[u]}],
   Axes -> False,
   PlotRange ->
    {{-1.02, 1.02}, {-1.02, 1.02}, {-1.02, 1.02}}]],
 {u, 0, 2 Pi, .1},
 AnimationRunning -> True]



Bob Hanlon




On Sun, Nov 17, 2013 at 6:22 PM, Narasimham <mathma18 at gmail.com> wrote:

> It appears an Animate-d graph can no more combine with an unanimated graph
> object.In following example,where skew lines join two points on two
> displaced circles as Hypar (one-sheet) generators, how to Show the static
> and dynamic components together?
>
> If juxtaposed Show succeeds, how to further leave permanent traces of
> generators?
>
> h = 0.5; dt = 0.8;
> HypPar[u_] =
>   Line[{{Cos[u], Sin[u], 0}, { Cos[u + dt], Sin[u + dt], h }}];
> Genrtr = Animate[
>   Graphics3D[HypPar[u], Axes -> False,
>    PlotRange -> {{-1.02, 1.02}, {-1.02, 1.02}, {-1.02, 1.02}},
>    AspectRatio -> 1], {u, 0, 2 Pi, .1}, AnimationRunning -> True]
> EndCircs =
>  ParametricPlot3D[{{ Cos[u + 1.5], Sin[u + 1.5] , 0}, {Cos[u], Sin[u],
>      h}}, {u, 0, 2 Pi}]
> Show[Genrtr, EndCircs]
>
> I hope you see the aim, viz.to visualize it the way we go about
> constructing a mechanical assembly.
>
> Regards
> Narasimham
>
>




  • Prev by Date: Re: Programming Fail
  • Next by Date: Re: Programming Fail
  • Previous by thread: Re: Animate cannot be combined?
  • Next by thread: Re: Animate cannot be combined?