Mathematica 9 is now available
Student Support Forum
Student Support Forum: 'Calculus Issues' topicStudent Support Forum > General > Archives > "Calculus Issues"

< Previous CommentHelp | Reply To Comment | Reply To Topic
Author Comment/Response
Bill Simpson
05/13/13 9:47pm

Solve tends to do well when it is given polynomials and often not do so well when given other more complicated things.

Your integrals don't look impossible, so let's try to find each of those first. Integrate gives complicated results that depend on whether b is less than or greater than 1. It isn't obvious from your description which b is so let's assume it is between 0 and 1 to start with.

In[1]:= f = Assuming[0 < b < 1, Integrate[2 \[Pi]*(100/x)*(Sqrt[1 + 10000/(x^4)]), {x, 1, b}]]

Out[1]= 100 \[Pi] (Sqrt[10001] - Sqrt[10000 + b^4]/b^2 - ArcCsch[100] + ArcCsch[100/b^2])

In[2]:= g = Assuming[0 < b < 1, Integrate[\[Pi] (100/x)^2, {x, 1, b}]]

Out[2]= (10000 (-1 + b) \[Pi])/b

Now let's try with b greater than 1

In[3]:= h = Assuming[1 < b, Integrate[2 \[Pi]*(100/x)*(Sqrt[1 + 10000/(x^4)]), {x, 1, b}]]

Out[3]= 100 \[Pi] (Sqrt[10001] - Sqrt[10000 + b^4]/b^2 - ArcCsch[100] + ArcCsch[100/b^2])

In[4]:= i = Assuming[1 < b, Integrate[\[Pi] (100/x)^2, {x, 1, b}]]

Out[4]= (10000 (-1 + b) \[Pi])/b

Now let's peek at a graph to see what is happening. We plot the difference of the two integrals and combine the plots for b<1 and b>1. We also give a PlotRange big enough to hold both plots so one doesn't get chopped off.

In[5]:= Show[Plot[f - 2618.17*g, {b, 1/2, 1}, PlotRange -> {{1/2, 2}, All}],
Plot[h - 2618.17*i, {b, 1, 2}]]

Out[5]= ...NicePlotSnipped...

Solve probably won' like those hyperbolic trig functions, but FindRoot will look for a zero.

In[6]:= FindRoot[f - 2618.17*g, {b, 1/2}]

Out[6]= {b -> 1.}

In[7]:= FindRoot[h - 2618.17*i, {b, 2}]

Out[7]= {b -> 1.}

Looking at the results, we can even try substituting 1 for b (using /.b->1 to do the substitution) and let Mathematica's default simplification show us what it finds.

In[8]:= 100 \[Pi] (Sqrt[10001] - Sqrt[10000 + b^4]/b^2 - ArcCsch[100] + ArcCsch[100/b^2]) == 2618.17*(10000 (-1 + b) \[Pi])/b /. b -> 1

Out[8]= True

Now, since you are looking for the amount of paint needed and the integral from 1 to 1 is going to give you zero area, I suspect it might be a good idea to look at the logic again.

URL: ,

Subject (listing for 'Calculus Issues')
Author Date Posted
Calculus Issues Christopher 05/13/13 12:14pm
Re: Calculus Issues Bill Simpson 05/13/13 9:47pm
< Previous CommentHelp | Reply To Comment | Reply To Topic