Re: a question about complex variable
- To: mathgroup at smc.vnet.net
- Subject: [mg21672] Re: [mg21620] a question about complex variable
- From: Andrzej Kozlowski <andrzej at tuins.ac.jp>
- Date: Fri, 21 Jan 2000 04:00:30 -0500 (EST)
- Sender: owner-wri-mathgroup at wolfram.com
First of all the answer you say you want to get is not always true. The
correct answer depends on the values of A and P. Take the simple case A =
3Pi/4 and P=Pi. Then your c will become I, its argument Pi/2 and absolute
value 1. On the other hand -2(P+Pi/4) is -10Pi/4 and Tan[A] is -1.
Mathematica however, can give you correct answers:
In[1]:=
c = (-I* Cos[2 P] - Sin[2 P]) Tan[A];
In[2]:=
argc = FullSimplify[ComplexExpand[Arg[c], TargetFunctions -> {Re, Im}],
A \[Element] Reals && P \[Element] Reals]
Out[2]=
ArcTan[-Sin[2 A] Sin[2 P], -Cos[2 P] Sin[2 A]]
In[3]:=
absc = FullSimplify[ComplexExpand[Abs[c], TargetFunctions -> {Re, Im}]]
Out[3]=
2
Sqrt[Tan[A] ]
This is the best you can do without more information about A and P.
For example, if you know that Tan[A]>0 you can now use:
In[4]:=
Simplify[absc, Tan[A] > 0]
Out[4]=
Tan[A]
Again, if, for example, you know that A lies between 0 and Pi/2 (first
quarter) you can further get:
In[5]:=
Simplify[argc, 0 < A < Pi/2]
Out[5]=
ArcTan[-Sin[2 P], -Cos[2 P]]
This means that the argument of c has tangent equal to Cot[2P] and also
tells you the quadrant in which it lies.
Andrzej Kozlowski
Toyama International University
JAPAN
http://sigma.tuins.ac.jp
> From: ZHU Xiaopeng <xpzhu at red.semi.ac.cn>
To: mathgroup at smc.vnet.net
> Date: Tue, 18 Jan 2000 02:35:10 -0500 (EST)
> To: mathgroup at smc.vnet.net
> Subject: [mg21672] [mg21620] a question about complex variable
>
> In my algebra computation, I obtain a expression:
> C = (- I Cos[2 P] - Sin[2 P]) Tan[A]
> P,A are real variables. Apperently, the argument of C is -2(P+Pi/4) and the
> absolute value of C is Tan[A]. But when I use Arg[C] and Abs[C], Mathematica
> tells me:
>
> Out[41]=Abs[(-I Cos[2 P] - Sin[2 P]) Tan[A]]
> Out[42]=Arg[(-I Cos[2 P] - Sin[2 P]) Tan[A]]
>
> This problem appeared at beginning of the computation. I have no idea to deal
> with it, so the expressions become longer and longer during the computation.
> Can somebody help me?
>
>
>