MathGroup Archive 2000

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Plotting/Inflection Point

  • To: mathgroup at smc.vnet.net
  • Subject: [mg26007] Re: [mg25968] Plotting/Inflection Point
  • From: BobHanlon at aol.com
  • Date: Wed, 15 Nov 2000 02:09:54 -0500 (EST)
  • Sender: owner-wri-mathgroup at wolfram.com

In a message dated 11/14/00 4:17:12 AM, bobmarley4u2c at my-deja.com writes:

>If I have a polynonial: f(x)=2x^3-3x^2-12, and I found that the
>Inflection Point is: (.5,-6.5). I want to plot the function and, show
>where the inflection point is by labeling it on the plot. How can I do
>that?
>Thank you.
>(P.S)
>I also need to show the Local MAX/MIN.
>

f[x_] := 2x^3 - 3x^2 - 12;

pts = {x, f[x]} /. 
      Join[Select[Solve[f[x] == 0, x], Element[x /. #, Reals] &], 
        Solve[f'[x] == 0, x], Solve[f''[x] == 0, x]] // Simplify

{{1/2*(1 + (25 - 4*Sqrt[39])^(1/3) + (25 + 4*Sqrt[39])^(1/3)), 
   1/4*(-48 - 3*(1 + (25 - 4*Sqrt[39])^(1/3) + (25 + 4*Sqrt[39])^(1/3))^2 + 
     (1 + (25 - 4*Sqrt[39])^(1/3) + (25 + 4*Sqrt[39])^(1/3))^3)}, {0, -12}, 
  {1, -13}, {1/2, -(25/2)}}

% // N

{{2.4775090051427453, -2.4868995751603507*^-14}, {0., -12.}, {1., -13.}, 
  {0.5, -12.5}}

Plot[f[x], {x, -1, 2.5}, Axes -> False, Frame -> True, 
    PlotStyle -> RGBColor[0, 0, 1], 
    Prolog -> {RGBColor[1, 0, 0], AbsolutePointSize[4], Point[#] & /@ pts, 
        Thread[Text[{"root     ", "local\n max\n\n", "\n\nlocal\n min", 
              "ip\n"}, pts]]}, PlotRange -> All, ImageSize -> {400, 250}];


  • Prev by Date: Re: MathLink
  • Next by Date: Re: Problem with Integrate
  • Previous by thread: Re: Plotting/Inflection Point
  • Next by thread: Mathematica