Re: Dirichlet generating function
- To: mathgroup at smc.vnet.net
- Subject: [mg26562] Re: [mg26551] Dirichlet generating function
- From: Andrzej Kozlowski <andrzej at tuins.ac.jp>
- Date: Fri, 5 Jan 2001 22:22:59 -0500 (EST)
- Sender: owner-wri-mathgroup at wolfram.com
I do not know if there is any way to do this using any number theory
packages known to me, but here is a rather simple (if a little ad hoc)
approach. We define a "formal function" s, where s[a] is supposed to
represent a^-s:
s[k_] /; k > 12 = 0;
s /: s[m_]*s[n_] := s[n*m];
s /: s[m_]^p_ := s[m^p];
The first rule is there of course to avoid any unnecessary computations. We
next define our Dirichlet function but using our just defined s:
In[6]:=
p1 = Product[1/(1 - n^(-s)), {n, 2, 12}] /. a_^(-s) -> s[a]
Out[6]=
1/((1 - s[2]) (1 - s[3]) (1 - s[4]) (1 - s[5]) (1 - s[6]) (1 - s[7]) (1 -
s[8]) (1 - s[9]) (1 - s[10]) (1 - s[11]) (1 - s[12]))
Next we need to define a list of variables and a length of expansion for
each at 0. One has to be careful here to use only as long lists as
necessary, otherwise the problem will explode. The following is sufficient
for this case:
t = {{s[2], 0, 3}, {s[3], 0, 2}, {s[4], 0, 1}, {s[5], 0, 1}, {s[6], 0,
1}, {s[7], 0, 1}, {s[8], 0, 1}, {s[9], 0, 1}, {s[10], 0, 1}, {s[11],
0, 1}, {s[12], 0, 1}};
(This can be automated using Table, but I could not be bothered to do so):
Finally
In[8]:=
Series[p1, Sequence @@ t] // Normal // Simplify
Out[8]=
1 + s[2] + s[3] + 2 s[4] + s[5] + 2 s[6] + s[7] + 3 s[8] + 2 s[9] + 2 s[10]
+ s[11] + 4 s[12]
seems to give the right answer.
--
Andrzej Kozlowski
Toyama International University
JAPAN
http://platon.c.u-tokyo.ac.jp/andrzej/
http://sigma.tuins.ac.jp/
on 01.1.5 2:34 PM, Arnold Knopfmacher at arnoldk at cam.wits.ac.za wrote:
> I wish to expand the product
> Product[1/(1-n^(-s)),{n,2,12}] to obtain output in the form of a Dirichlet
> series,
> 1+2^(-s)+3^(-s)+2*4^(-s)+5^(-s)+2*6^(-s)+...4*12^(-s)+...
>
> (The coefficients of m^(-s) in the above series give the number of
> factorizations of m into factors greater than 1. E.g. 12 can be factored
> in 4 ways, as 12 or 6*2 or 4*3 or 3*2*2).
>
> Thanks
>
>
> Arnold Knopfmacher
> Dept of Computational and Applied Maths
> Witwatersrand University
> Johannesburg 2050
> South Africa
> http://www.wits.ac.za/science/number_theory/arnold.htm
> Fax: 2711-4039317
> Phone: 2711- 717-6121
> email: arnoldk at gauss.cam.wits.ac.za
>
>
--
Andrzej Kozlowski
Yokohama, JAPAN
http://platon.c.u-tokyo.ac.jp/andrzej/
http://sigma.tuins.ac.jp/