MathGroup Archive 2005

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: NMinimize--problem with a min-max problem

  • To: mathgroup at smc.vnet.net
  • Subject: [mg55804] Re: [mg55753] NMinimize--problem with a min-max problem
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Wed, 6 Apr 2005 03:12:05 -0400 (EDT)
  • Reply-to: hanlonr at cox.net
  • Sender: owner-wri-mathgroup at wolfram.com

expr=(Log[x]+4/3 z Log[1-x])/(2 (3/4+z));

solnx=Solve[D[expr,x]==0,x][[1]]

{x -> 3/(4*z + 3)}

solnz=Solve[D[expr/.solnx,z]==0,z][[1]]

{z -> 3/4}

solnx=solnx/.solnz

{x -> 1/2}

expr/.solnx/.solnz

-((2*Log[2])/3)

%//N

-0.46209812037329684

Clear[fun1];
fun1[z_?NumericQ] := 
    NMaximize[{(Log[x]+4/3 z Log[1-x])/(2 (3/4+z)), 
          0<x<1},{x}][[1]];

Off[NMaximize::nnum];

NMinimize[fun1[z],z]

{-0.4620981203732968, {z -> 0.7499999786528403}}


Bob Hanlon

> 
> From: "David" <isolanoster at gmail.com>
To: mathgroup at smc.vnet.net
> Date: 2005/04/05 Tue AM 03:21:55 EDT
> To: mathgroup at smc.vnet.net
> Subject: [mg55804] [mg55753] NMinimize--problem with a min-max problem
> 
> Hello,
> 
> I'm trying to solve numerically the following problem:
> 
> min{z}max{y,x} f{x,y,z}
> 
> I first do the maximization:
> 
> fun1[z_] := NMaximize[{(
>   Log[x] + 4/3 z Log[
>       y])/(2 (3/4 + z)), x > 0, y > 0, x + y == 1}, {x, y}][[1]]
> 
> I can plot fun1[z] (the solution is at z=.75,x=y=1/2) however NMinimize
> does accept the definition of fun1[z] as:
> 
> NMinimize[fun1[z], z]
> 
> yields error. 
> 
> Any suggestion?
> 
> Thank you in advance,
> 
> David
> 
> 


  • Prev by Date: Re: 3D graphics domain
  • Next by Date: Re: mathlink and cygwin
  • Previous by thread: Re: NMinimize--problem with a min-max problem
  • Next by thread: 3D graphics domain