MathGroup Archive 2005

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Domain and range

  • To: mathgroup at smc.vnet.net
  • Subject: [mg54126] Re: Domain and range
  • From: Paul Abbott <paul at physics.uwa.edu.au>
  • Date: Fri, 11 Feb 2005 03:33:40 -0500 (EST)
  • Organization: The University of Western Australia
  • References: <cud82o$33c$1@smc.vnet.net>
  • Sender: owner-wri-mathgroup at wolfram.com

In article <cud82o$33c$1 at smc.vnet.net>,
 "DJ Craig" <spit at djtricities.com> wrote:

> How can I make Mathematica give me either a list or an inequality
> representing all real values of x that will make f[x] either undefined,
> imaginary, or infinite?  For example, if f[x] := (2x^2-18)/(x+3) then x
> != {-3}.  (-3 would give a 0 in the denominator)
> Secondly, how can I find all real numbers that CANNOT be returned by
> f[x] for any real, finite value of x.  In the example, f[x] != {-12}.

Some ideas. For your function,

  f[x_] := (2 x^2 - 18)/(x + 3)

you can find the poles as follows

  Solve[Denominator[f[x]] == 0, x]
  {{x -> -3}}

This is a removable singularity.

  Limit[f[x], x -> -3]
  -12

Here is the simplified function:

  g[x_] = Simplify[f[x]]
  2 (x - 3)

Using Interval arithmetic, we see that -12 is exlcuded:

  g[Interval[{-Infinity, -3}]]
  Interval[{-Infinity, -12}]

  g[Interval[{-3, Infinity}]]
  Interval[{-12, Infinity}]

> As a second example, ArcSin[x] only returns a real, finite number when
> -1 <= x <= 1.  

Here you can use

  Reduce[Element[ArcSin[x], Reals], x]
  -1 <= x <= 1

> When it is passed a real, finite number, it can only
> return values where -pi/2 <= ArcSin[x] <= pi/2.

or Interval arithmetic:

  ArcSin[Interval[{-1, 1}]]
  Interval[{-(Pi/2), Pi/2}]

Cheers,
Paul

-- 
Paul Abbott                                   Phone: +61 8 6488 2734
School of Physics, M013                         Fax: +61 8 6488 1014
The University of Western Australia      (CRICOS Provider No 00126G)         
35 Stirling Highway
Crawley WA 6009                      mailto:paul at physics.uwa.edu.au 
AUSTRALIA                            http://physics.uwa.edu.au/~paul


  • Prev by Date: Re: Newbie question Re: C# and Mathematica via NETLink
  • Next by Date: Re: Newbie question Re: C# and Mathematica via NETLink
  • Previous by thread: Domain and range
  • Next by thread: Re: Domain and range