Re: find area bounded by three linear functions
- To: mathgroup at smc.vnet.net
- Subject: [mg68368] Re: [mg68357] find area bounded by three linear functions
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Thu, 3 Aug 2006 06:06:25 -0400 (EDT)
- Reply-to: hanlonr at cox.net
- Sender: owner-wri-mathgroup at wolfram.com
Needs["Graphics`"];
InequalityPlot[{x>3y,x+y>0,7x+3y<24},
{x,-1,7},{y,-10,3},
Epilog->{
Text["x = 3 y",{1.5,0.5},{1,-1}],
Text["x + y = 0",{3,-3},{1,1}],
Text["7x + 3y = 24",{4.5,-2.5},{-1,-1}]},
PlotRange->{{-1,7},{-7,2}}];
eqns={x==3y,x+y==0,7x+3y==24};
Solve[#,{x,y}]&/@Subsets[eqns, {2}]
{{{x -> 0, y -> 0}}, {{x -> 3, y -> 1}},
{{x -> 6, y -> -6}}}
Integrate[1,{x,0,3},{y,-x,x/3}]+
Integrate[1,{x,3,6},{y,-x,(24-7x)/3}]
12
Integrate[Boole[x>3y&&x+y>0&&7x+3y<24],
{x,-Infinity,Infinity},{y,-Infinity,Infinity}]
12
Bob Hanlon
---- T Harris <tdh1967 at bellsouth.net> wrote:
> How can I get Mathematica to find the area of the region bounded by all
> three of the following linear functions? I have tried searching and can't
> find it. What do I search for to find the commands to accomplish this? I
> calculated by hand and come up with about 3.1623 sq. units for area above
> the x-axis and 8.8378 sq. units below it. The total area for the scalene
> triangle formed is 12 square units by my calculations using Heron's formula.
>
> X=3Y; X+Y=0; 7X + 3Y =24
>
> Thanks,
>
> T Harris
>