Re: Symmetric polynomials
- To: mathgroup at smc.vnet.net
- Subject: [mg69002] Re: [mg68940] Symmetric polynomials
- From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
- Date: Sat, 26 Aug 2006 02:04:48 -0400 (EDT)
- References: <200608250934.FAA09161@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
On 25 Aug 2006, at 11:34, shubi at nusun.jinr.ru wrote:
> Dear All,
>
> Is the possibility in "Mathematica" express symmetric functions,
> for
> example:
>
> P=y1^2 y2 y3 + y1 y2^2 y3 + y1 y2 y3^2 + y1^2 y2 y4 +
> y1 y2^2 y4 + y1^2 y3 y4 + y2^2 y3 y4 + y1 y3^2 y4 +
> y2 y3^2 y4 + y1 y2 y4^2 + y1 y3 y4^2 + y2 y3 y4^2;
>
> by the standard symmetric polynomials:
> S1=y1+y2+y3+y4;
> S2=y1^2+y2^2+y3^2+y4^2;
> S3=y1^3+y2^3+y3^3+y4^3;
> . . .
>
> Best regards
> Nodar Shubitidze
> Joint Institute for Nuclear Research
> Dubna, Moscow region, Russia
>
You can do it as follows.
P = y1^2 y2 y3 + y1 y2^2 y3 + y1 y2 y3^2 + y1^2 y2 y4 +
y1 y2^2 y4 + y1^2 y3 y4 + y2^2 y3 y4 + y1 y3^2 y4 +
y2 y3^2 y4 + y1 y2 y4^2 + y1 y3 y4^2 + y2 y3 y4^2;
s[i_] := y1^i + y2^i + y3^i + y4^i
ideal = Table[S[i] - s[i], {i, 1, 4}];
vars = Join[{y1, y2, y3, y4}, Table[S[i], {i, 1, 4}]];
g = GroebnerBasis[ideal, vars, MonomialOrder -> EliminationOrder];
Now your polynomial is given by:
p = PolynomialReduce[P, g, vars][[2]]
(1/2)*S[2]*S[1]^2 - S[3]*S[1] - S[2]^2/2 + S[4]
where S[1], S[2], S[3] and S[4] are your S1, S2 ...
Checking:
ExpandAll[p /. S[i_] -> s[i]] == P
True
Andrzej Kozlowski
- References:
- Symmetric polynomials
- From: shubi@nusun.jinr.ru
- Symmetric polynomials