MathGroup Archive 2006

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Problem with LaplaceTransform and InverseLaplaceTransform

  • To: mathgroup at smc.vnet.net
  • Subject: [mg67768] Re: Problem with LaplaceTransform and InverseLaplaceTransform
  • From: ab_def at prontomail.com
  • Date: Thu, 6 Jul 2006 06:55:01 -0400 (EDT)
  • References: <e7td5h$3kh$1@smc.vnet.net><e85gr9$kkv$1@smc.vnet.net>
  • Sender: owner-wri-mathgroup at wolfram.com

The notation Integrate[f[tau], {tau, 0-, t}] is usually taken to mean

Limit[Integrate[f[tau], {tau, eps, t}], eps -> 0, Direction -> 1]

(so we bypass the issue of Integrate[DiracDelta[t], {t, 0, Infinity}]
== 1/2):

In[1]:= Assuming[eps < 0 && t > 0,
    Integrate[DiracDelta[tau], {tau, eps, t}] +
      2*Sum[Integrate[(-1)^k*DiracDelta[tau - Pi*k],
          {tau, eps, t}],
        {k, Infinity}] ] //
  Limit[#, eps -> 0, Direction -> 1]&

Out[1]= Piecewise[{{1, t < Pi}}, (-1)^Floor[t/Pi]]

Another way is to always define the functions so that they vanish for t
< 0 (multiply by UnitStep[t] if necessary). That way we needn't worry
about the integration limits (can integrate everything from -Infinity
to t) but should be careful to avoid constructs like UnitStep[t]^2:

In[2]:= Assuming[k >= 1,
    Integrate[DiracDelta[tau], {tau, -Infinity, t}] +
      2*Sum[Integrate[(-1)^k*DiracDelta[tau - Pi*k],
          {tau, -Infinity, t}],
        {k, Infinity}] ]

Out[2]= UnitStep[t] + ((-1)^Ceiling[Max[1, (t*UnitStep[-t])/Pi]] +
(-1)^Floor[(t*UnitStep[t])/Pi])*UnitStep[-Ceiling[Max[1,
(t*UnitStep[-t])/Pi]] + (t*UnitStep[t])/Pi]

Maxim Rytin
m.r at inbox.ru

bghiggins at ucdavis.edu wrote:
> Maxim,
>
> When you include the zero in the integration range you do not get the
> same result. The result is off by a factor of 1/2. Is this a bug in
> Mathematica or am I missing something?
>
> Integrate[DiracDelta[Ï?], {Ï?, 0, t}, Assumptions -> t â??
>         Reals] + 2*Sum[Integrate[(-1)^k*DiracDelta[Ï? - Pi*
>           k], {Ï?, 0, t}, Assumptions -> {t
>         â?? Reals}], {k, Infinity}] // Simplify
>
> Piecewise[{{1/2, t < Pi}}, -(1/2) + (-1)^Floor[t/Pi]]
>
> Your result is
>
> Piecewise[{{1, Inequality[0, LessEqual, t, Less, Pi]},
> {(-1)^Floor[t/Pi], t >= Pi}}]
>
> These calculations were done on a Mac OSX (10.4.6)  with Mathematica
> Version 5.2
>
> Cheers,
>
> Brian
>
>
> ab_def at prontomail.com wrote:
> > aXi wrote:
> > > Can someone point me to site that would help me in using Mathematica
> > > 5.2for purpose of calculations related to Systhems theory. I'm having
> > > trouble with several topics... for example doing
> > > InverseLaplaceTransform of function:
> > >
> > > (1/s) * (TanH[pi*s/2])
> > >
> > > Thanks in advance!
> >
> > If you want the inverse Laplace transform of Tanh[Pi*s/2]/s, it can be
> > found as follows. First take the transform of Tanh[Pi*s/2]:
> >
> > In[1]:= fs = Tanh[Pi*s/2]/s;
> >
> > In[2]:= InverseLaplaceTransform[s*fs, s, t]
> >
> > Out[2]= DiracDelta[t] + 2*Sum[(-1)^K$40*DiracDelta[(-K$40)*Pi + t],
> > {K$40, 1, Infinity}]
> >
> > Then integrate the result:
> >
> > In[3]:= Integrate[DiracDelta[t], t] +
> >   2*Sum[Integrate[(-1)^k*DiracDelta[t - Pi*k], t], {k, Infinity}]
> >
> > Out[3]= UnitStep[t] + (-1 + (-1)^Floor[t/Pi])*UnitStep[-1 + t/Pi]
> >
> > Strictly speaking, we need to evaluate Integrate[f[tau], {tau, 0-, t}],
> > 'including' the zero in the integration range.
> >
> > It is easy to see that the result is equal to (-1)^Floor[t/Pi] or
> > Sign[Sin[t]]. Here's a check:
> >
> > In[4]:= LaplaceTransform[Sign[Sin[t]], t, s] - fs // Simplify
> > 
> > Out[4]= 0
> > 
> > Maxim Rytin
> > m.r at inbox.ru


  • Prev by Date: Re: Another limit problem
  • Next by Date: RE: Subscript for a variable
  • Previous by thread: Re: Problem with LaplaceTransform and InverseLaplaceTransform
  • Next by thread: Re: Color names and the 10 elementary colors?