Re: Problem with Limit
- To: mathgroup at smc.vnet.net
- Subject: [mg67931] Re: Problem with Limit
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Mon, 17 Jul 2006 06:51:47 -0400 (EDT)
- Organization: The University of Western Australia
- References: <e5jri2$dos$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
In article <e5jri2$dos$1 at smc.vnet.net>,
"Tony Harker" <a.harker at ucl.ac.uk> wrote:
> Can anybody explain why, for
>
> t =Sqrt[(k*m1 + k*m2 + m1*g + m2*g -
> (1/2)*Sqrt[4*(m1 + m2)^2*(k + g)^2 - 16*k*m1*m2*(k + 2*g)])/
> (m1*m2)]/(1 + (k*m1 - k*m2 + m1*g - m2*g +
> (1/2)*Sqrt[4*(m1 + m2)^2*(k + g)^2 - 16*k*m1*m2*(k + 2*g)])^2/
> (4*m1*m2*g^2)) + Sqrt[(k*m1 + k*m2 + m1*g + m2*g +
> (1/2)*Sqrt[4*(m1 + m2)^2*(k + g)^2 - 16*k*m1*m2*(k + 2*g)])/
> (m1*m2)]/(1 + ((-k)*m1 + k*m2 - m1*g + m2*g +
> (1/2)*Sqrt[4*(m1 + m2)^2*(k + g)^2 - 16*k*m1*m2*(k + 2*g)])^2/
> (4*m1*m2*g^2));
>
> Limit[t, g -> 0]
> Limit[Together[t], g -> 0]
>
> both give zero, whereas
>
> Limit[Simplify[Together[t]], g -> 0]
>
> gives a non-zero result?
Maxim Rytin has explained why.
Instead of using Limit I prefer to use Series. Direct use of Series
still requires "cancelling singularities". If one considers the case
m1 > m2, the first part, t[[1]], is straightforward,
Simplify[t[[1]] + O[g], k > 0 && m1 > m2] // Normal
0
whereas the second needs to be handled by considering the Numerator and
Denominator separately, and simplifying the series expansions _before_
taking the ratio.
Simplify[ Numerator[t[[2]]] + O[g], k > 0 && m1 > m2]/
Simplify[ Denominator[t[[2]]] + O[g], k > 0 && m1 > m2] // Normal
Sqrt[2] Sqrt[k/m2]
The converse is true for m1 < m2, but the answer is unchanged. In the
case that m1 -> m2, one gets the answer immediately:
(t /. m1 -> m2) + O[g] // Normal
Sqrt[2] Sqrt[k/m2]
Alternatively, series expansion in m1 about m2 and g about 0 is
informative:
Simplify[Series[t, {m1, m2, 2}, {g, 0, 2}]]
Cheers,
Paul
_______________________________________________________________________
Paul Abbott Phone: 61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
AUSTRALIA http://physics.uwa.edu.au/~paul