Re: Strange empty set of solutions
- To: mathgroup at smc.vnet.net
- Subject: [mg71833] Re: Strange empty set of solutions
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Thu, 30 Nov 2006 06:05:40 -0500 (EST)
- Organization: The University of Western Australia
- References: <ekh7pg$sgs$1@smc.vnet.net>
In article <ekh7pg$sgs$1 at smc.vnet.net>,
José Carlos Santos <jcsantos at fc.up.pt> wrote:
> I have a certain 3 x 3 numerical matrix M. If I type
>
> Solve[M.{a,b,c}=={0,0,0},{a,b,c}]
>
> I get
>
> {{a -> 0. + 0.0410026 c, b -> 0. + 1.35294 c}}
along with a warning message, that you have deleted.
> However, if I type
>
> Solve[{M.{a,b,c}=={0,0,0},a^2+b^2+c^2==1},{a,b,c}]
>
> I get the empty set. Why is that? I should get two solutions!
Look up the documentation for Solve to find out why -- and use Reduce
instead.
For example, with
M={{0.2429717091736855, 0.06206063726712955, -0.09392679038675521},
{0.0992369012615341, 0.6047269186862279, -0.8222282083350113},
{0.6768075377204311, 0.128145446007053, -0.20112396846691802}};
then you get
Solve[M.{a,b,c}=={0,0,0},{a,b,c}]
{{a -> 0. + 0.0410026*c, b -> 0. + 1.35294*c}}
Using Reduce, you get two equivalent solutions:
Reduce[{M . {a, b, c} == {0, 0, 0}, a^2 + b^2 + c^2 == 1},
{a, b, c}, Backsubstitution -> True]
(a == -0.024364357796705177 && b == -0.8039371707519599 &&
c == -0.594214947264446) ||
(a == 0.024364357796705177 && b == 0.8039371707519599 &&
c == 0.594214947264446)
Of course, you could just use NullSpace:
NullSpace[M]
{{0.024364357796705243, 0.8039371707519597, 0.5942149472644462}}
First[%].First[%]
1
Cheers,
Paul
_______________________________________________________________________
Paul Abbott Phone: 61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
AUSTRALIA http://physics.uwa.edu.au/~paul