       Re: Definite Integration vs Newton-Leibniz formula

• To: mathgroup at smc.vnet.net
• Subject: [mg74332] Re: Definite Integration vs Newton-Leibniz formula
• From: Peter Pein <petsie at dordos.net>
• Date: Mon, 19 Mar 2007 01:58:20 -0500 (EST)
• References: <etik7c\$j46\$1@smc.vnet.net>

```dimitris schrieb:
> Consider the following function
>
> f[x_] = Sin[x^3]Log[x]
>
> Then
>
> Integrate[f[x], {x, 0, 1}]
> {% // N, NIntegrate[f[x], {x, 0, 1}]}
>
> (-(1/16))*HypergeometricPFQ[{2/3, 2/3}, {3/2, 5/3, 5/3}, -(1/4)]
> {-0.060865478966467726, -0.06086547896286495}
>
> Let evaluate first the indefinite integral and then apply the Newton-
> Leibniz formula.
>
> F[x_] = Integrate[Sin[x^3]Log[x], x]
>
> (1/(6*x^2))*(-3*I*x^3*HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3}, (-
> I)*x^3] +
>    3*I*x^3*HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3}, I*x^3] +
>    (3*(((-I)*x^3)^(2/3) + (I*x^3)^(2/3))*Gamma[4/3] - ((-
> I)*x^3)^(2/3)*Gamma[1/3, (-I)*x^3] - (I*x^3)^(2/3)*Gamma[1/3,
> I*x^3])*Log[x])
>
> Limit[F[x], x -> 1, Direction -> 1] - Limit[F[x], x -> 0, Direction ->
> -1]
> (1/2)*I*(-HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3}, -I] +
> HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3}, I])
>
> Of course
>
> %//N//Chop
> -0.060865478966467726
>
> as it should be.
>
> But why the definite integral return a different value?
>
> I believe that integrals like the above are evaluated by first
> determination of the antiderivative and then evaluation
> at endpoints.
>
> Using a code for Limit adopted from a post Daniel Lichtblau, in order
> to see what limits are evaluated
> by Integrate I got more confused.
>
> Unprotect[Limit];
> Limit[a___] := Null /; (Print[InputForm[limit[a]]]; False)
>
> Integrate[f[x],{x,0,1}]
>
> limit[0, x -> 0, Direction -> -1, Assumptions -> True]
> limit[(-1 + x)^2*(3*Cos - Sin/2) + (-1 + x)*Sin, x -> 1,
> Direction -> 1,
>     Assumptions -> True]
> (-(1/16))*HypergeometricPFQ[{2/3, 2/3}, {3/2, 5/3, 5/3}, -(1/4)]
>
> Can somebody give me insight what is going?
>
> Thanks a lot
> Dimitris
>
>

Hi Dimitris,

these limits occur during the search for singularities at the endpoints:

f[x_] := Sin[x^3]*Log[x];
Off[General::spell1]; Unprotect[Limit];
Limit[a___] := Null /;(Print[InputForm[limit[a]]]; False)

Limit[Normal[Series[f[x], {x, #1, 2}]], x -> #1]& /@ {0, 1};
-->
limit[0, x -> 0]
limit[(-1 + x)^2*(3*Cos - Sin/2) + (-1 + x)*Sin, x -> 1]

I'm afraid, I can only guess, why

Integrate[f[x], {x, 0, 1}]
--> (-(1/16))*HypergeometricPFQ[{2/3, 2/3}, {3/2, 5/3, 5/3}, -(1/4)]

and

{-1, 1} .(Limit[F[z], z -> #1, Direction -> #2] & @@@{{0, -1}, {1, 1}})
--> (1/2)*I*(-HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3}, -I] +
HypergeometricPFQ[{1/3, 1/3}, {4/3, 4/3},  I])

differ formally.

Maybe Mathematica has got the latter and does internally sth. like

a[k_][x_] = FunctionExpand[
(Pochhammer[1/3, k]/Pochhammer[4/3, k])^2 * x^k / k!]
--> x^k/((1 + 3*k)^2*Gamma[1 + k])

FullSimplify[(I/2)*(a[k][I] - a[k][-I]), k >= 0 && k \[Element] Integers]
--> -(Sin[(k*Pi)/2]/((1 + 3*k)^2*k!))

FullSimplify[% /. k -> 2*i - 1, i \[Element] Integers && i >= 1]
--> (-1)^i/(4*(1 - 3*i)^2*Gamma[2*i])

Sum[%, {i, 1, Infinity}]
-->(-(1/16))*HypergeometricPFQ[{2/3, 2/3}, {3/2, 5/3, 5/3}, -(1/4)]

Peter

```

• Prev by Date: Normal for Limit : Example
• Next by Date: Re: Two successive FindMinimum -> Bug?
• Previous by thread: Definite Integration vs Newton-Leibniz formula