MathGroup Archive 2008

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Simplification question

  • To: mathgroup at smc.vnet.net
  • Subject: [mg84754] Re: [mg84726] Simplification question
  • From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
  • Date: Sat, 12 Jan 2008 05:20:42 -0500 (EST)
  • References: <200801120304.WAA19248@smc.vnet.net>

Yes. For example:

In[1]:= p = Root[a[1, 1]*a[2, 1]*#1^4 -
           2*Sqrt[a[1, 1]*a[1, 2]*a[2, 1]*a[2, 2]]*#1^2 +
           a[1, 2]*a[2, 2] & , 3];
q = (a[1, 2]^(1/4)*a[2, 2]^(1/4))/(a[1, 1]^(1/4)*a[2, 1]^(1/4));

In[3]:=  Reduce[p - q != 0 && a[1, 1] >= 0 && a[1, 2] >= 0 && a[2, 1]  
 >= 0 &&
   a[2, 2] >= 0, {a[1, 1], a[1, 2], a[2, 2], a[2, 1]}]
Out[3]= False


On 12 Jan 2008, at 12:04, Yaroslav Bulatov wrote:

> Is there a way to prove that the following 2 expressions are
> equivalent over positives using Mathematica?
>
> Root[a[1, 2] a[2, 2] - 2 Sqrt[a[1, 1] a[1, 2] a[2, 1] a[2, 2]] #1^2 +
> a[1, 1] a[2, 1] #1^4 &, 3]
> (a[1, 2]^(1/4) a[2, 2]^(1/4))/(a[1, 1]^(1/4) a[2, 1]^(1/4))
>
> ------------------
> PS: I got the two these two by following the recipe in
> http://www.yaroslavvb.com/papers/djokovic-note.pdf for finding
> diagonal/doubly-stochastic/diagonal decomposition of a 2x2 symbolic
> matrix in two different ways. Simpler solution came from forming
> Langrangian and using Solve, more complicated one from the built-in
> Minimize function)
>
> f[x_] := Times @@ x;
> A = Array[a, {2, 2}];
> (* Method 1 *)
> posCons = # > 0 & /@ (Flatten[A]~Join~{x1, x2});
> min = Minimize[{f[A.{x1, x2}]}~
>    Append~(And @@ ({f[{x1, x2}] == 1}~Join~posCons)), {x1, x2}];
> Assuming[
> And @@ posCons,
> FullSimplify[min]
> ]
>
> (* Method 2 *)
> L[x1_, x2_, \[Lambda]_] :=
>  f[A.{x1, x2}] - \[Lambda] (f[{x1, x2}] - 1);
> eqs = Table[
>   D[L[x1, x2, \[Lambda]], var] == 0, {var, {x1, x2, \[Lambda]}}];
> Solve[eqs, {x1, x2}, {\[Lambda]}] // Last
>



  • Prev by Date: Re: changing the name of exported file without typing
  • Next by Date: Re: Simplification question
  • Previous by thread: Simplification question
  • Next by thread: Re: Simplification question