MathGroup Archive 2008

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Solving a DE using Mathematica

  • To: mathgroup at smc.vnet.net
  • Subject: [mg90483] Re: [mg90424] Solving a DE using Mathematica
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Thu, 10 Jul 2008 06:38:31 -0400 (EDT)
  • Reply-to: hanlonr at cox.net

eqn = Rationalize[(-l^2 - m^2 + n^2/(r + 0.016 z)^2) Z[z] + Z''[z] == 
    0, 0];

soln = DSolve[eqn, Z[z], z][[1]] // FunctionExpand // Simplify

{Z[z] -> (1/Sqrt[Pi])*
       ((Sqrt[Sqrt[l^2 + m^2]*(125*r + 2*z)]*
             (2^(I*Sqrt[15625*n^2 - 1])*BesselK[
                    (-(1/2))*I*Sqrt[15625*n^2 - 1], 
                    (1/2)*Sqrt[l^2 + m^2]*(125*r + 2*z)]*C[2] + 
                Sqrt[Pi]*BesselI[(-(1/2))*I*
                      Sqrt[15625*n^2 - 1], (1/2)*Sqrt[l^2 + m^2]*
                      (125*r + 2*z)]*C[1]*Gamma[
                    1 - (1/2)*I*Sqrt[15625*n^2 - 1]]))/
          2^(I*Sqrt[15625*n^2 - 1]))}

d = NestList[D[#, z] &, soln[[1]], 2] // Simplify;

eqn[[1]] /. d // FullSimplify

0

eqn /. d // FullSimplify

True


Bob Hanlon

---- Greg <starwar636 at aol.com> wrote: 

=============
I'm having problems solving this problem although it should appear pretty straightfoward:

(-l^2 - m^2 + n^2/(r + 0.016 z)^2) Z[z] + Z''[z] == 0

I am solving for Z[z].  These are the lines I use:

DSolve[Above Equation, Z[z], z]

I get an odd solution so I do a solution check plugging back in Z[z] and Z''[z] yet I don't get 0.  In the above, l,m,n,r are all constants.




  • Prev by Date: RE: How to show tick labels w/o showi the tick marks?
  • Next by Date: Defining Functions and Simplifying Solutions
  • Previous by thread: Re: Solving a DE using Mathematica
  • Next by thread: Help with 3 dimensional Fourier Integral