Re: extracting points and projecting
- To: mathgroup at smc.vnet.net
- Subject: [mg98150] Re: [mg98099] extracting points and projecting
- From: DrMajorBob <btreat1 at austin.rr.com>
- Date: Tue, 31 Mar 2009 04:20:30 -0500 (EST)
- References: <200903300942.EAA08024@smc.vnet.net>
- Reply-to: drmajorbob at bigfoot.com
How about:
g = ContourPlot[Arg[Gamma[x + I*y]] == 0, {x, -10, 10}, {y, -10, 10},
PlotPoints -> 100]
pts = First@Cases[g, x_GraphicsComplex :> First[x]];
j1[x_, y_] := 2 x/(1 + x^2 + y^2)^2
j2[x_, y_] := 2 y/(1 + x^2 + y^2)^2
j3[x_, y_] := (-1 + x^2 + y^2)/(1 + x^2 + y^2)
Timing[one = pts /. {x_, y_} :> {j1[x, y], j2[x, y], j3[x, y]};]
{0.127167, Null}
one // Dimensions
{8146, 3}
Graphics3D[Point@one]
or
Timing[two = Outer[#2 @@ #1 &, pts, {j1, j2, j3}, 1, 1];]
{0.171188, Null}
one == two
True
Bobby
On Mon, 30 Mar 2009 04:42:57 -0500, Cristina Ballantine
<cballant at holycross.edu> wrote:
> I would like to extract the points from the following ContourPlot
>
> g=ContourPlot[Arg[Gamma[x + I*y]] == 0, {x, -10, 10}, {y, -10, 10},
> PlotPoints -> 100]
>
> I can do this with
>
> pts = First@Cases[g, x_GraphicsComplex :> First[x]]
>
> Then I would like to map this list of points onto the Riemann sphere.
> The projection is performed through
>
> j1[x_, y_] := 2 x/(1 + x^2 + y^2)^2
> j2[x_, y_] := 2 y/(1 + x^2 + y^2)^2
> j3[x_, y_] := (-1 + x^2 + y^2)/(1 + x^2 + y^2)
>
> I need to generate a list of three dimensional points (j1[x,y], j2[x,y],
> j2[x,y]) from pts and plot them. I am unable to generate the list of
> three dimensional points. Any help is very much appreciated.
>
> Cristina
>
--
DrMajorBob at bigfoot.com
- References:
- extracting points and projecting
- From: "Cristina Ballantine" <cballant@holycross.edu>
- extracting points and projecting