Re: Help generalizing Liouville's Polynomial Identity
- To: mathgroup at smc.vnet.net
- Subject: [mg103653] Re: [mg103596] Help generalizing Liouville's Polynomial Identity
- From: "Kurt TeKolste" <tekolste at fastmail.us>
- Date: Thu, 1 Oct 2009 06:40:21 -0400 (EDT)
- References: <200909291140.HAA25752@smc.vnet.net>
Second response, correction to the first response.
There was an error in my previous definition of "nextP" and it looks as
if the answer is 10 variables.
Here is the definition of the pattern of the polynomial as a function of
the number of variables in use:
nextP[n_] :=
Total[Flatten[
Table[(x[i] + signj x[j] + signk x[k] + signl x[l])^4, {i, 1,
n - 3}, {j, i + 1, n - 2}, {k, j + 1, n - 1}, {l, k + 1,
n}, {signj, {-1, 1}}, {signk, {-1, 1}}, {signl, {-1, 1}}]]]
We search for reducible polynomials of this form and find that it is
reducible if there are 10 variables:
In[72]:= IrreduciblePolynomialQ[nextP[#]] & /@ Range[5, 10]
Out[72]= {True, True, True, True, True, False}
And we factor it immediately to the desired form:
In[70]:= Factor[nextP[10]]
Out[70]= 672 (x[1]^2 + x[2]^2 + x[3]^2 + x[4]^2 + x[5]^2 + x[6]^2 +
x[7]^2 + x[8]^2 + x[9]^2 + x[10]^2)^2
Noting that your formula also is valid with one variable:
{x[1]^2)^2 == x[1]^4
We have identities of your form for
1, 3, 7, 10 variables
with coefficients
1, 6, 60, 672
Feeling brave we extend the pattern to one more term in each of the sums
and guess that it will factor with 13 variables
anotherP[n_] :=
Total[Flatten[
Table[(x[i] + signj x[j] + signk x[k] + signl x[l] +
signm x[m])^4, {i, 1, n - 4}, {j, i + 1, n - 3}, {k, j + 1,
n - 2}, {l, k + 1, n - 1}, {m, l + 1,
n}, {signj, {-1, 1}}, {signk, {-1, 1}}, {signl, {-1,
1}}, {signm, {-1, 1}}]]]
And it works::
In[74]:= IrreduciblePolynomialQ[anotherP[13]]
Out[74]= False
So does the desired factorizaton:
In[75]:= Factor[anotherP[13]]
Out[75]= 7920 (x[1]^2 + x[2]^2 + x[3]^2 + x[4]^2 + x[5]^2 + x[6]^2 +
x[7]^2 + x[8]^2 + x[9]^2 + x[10]^2 + x[11]^2 + x[12]^2 + x[13]^2)^2
Now our sequence has
1,2,7,10,13 variables
Coefficients of 1,6,60,672, and 7920
I haven't thought of a clever way to build these polynomials, but my
guess is that your conjecture is true for 16, 19, ... variables. The
sequence of coefficients is not in the encyclopedia
(http://www.research.att.com/~njas/sequences/index.html?q=1%2C+6%2C+60%2C+672%2C+7290&language=english&go=Search)
But I couldn't resist doing anther with this result
In[87]:= yetAnotherP[n_] :=
Total[Flatten[
Table[(x[i] + signj x[j] + signk x[k] + signl x[l] + signm x[m] +
signp x[p])^4, {i, 1, n - 5}, {j, i + 1, n - 4}, {k, j + 1,
n - 3}, {l, k + 1, n - 2}, {m, l + 1, n - 1}, {p, m + 1,
n}, {signj, {-1, 1}}, {signk, {-1, 1}}, {signl, {-1,
1}}, {signm, {-1, 1}}, {signp, {-1, 1}}]]]
In[88]:= IrreduciblePolynomialQ[yetAnotherP[16]]
Out[88]= False
In[89]:= Factor[yetAnotherP[16]]
Out[89]= 96096 (x[1]^2 + x[2]^2 + x[3]^2 + x[4]^2 + x[5]^2 + x[6]^2 +
x[7]^2 + x[8]^2 + x[9]^2 + x[10]^2 + x[11]^2 + x[12]^2 + x[13]^2 +
x[14]^2 + x[15]^2 + x[16]^2)^2
So the sequence of coefficients of 1,6,60,672,7920, and 96096.
ekt
On Tue, 29 Sep 2009 07:40 -0400, "TPiezas" <tpiezas at gmail.com> wrote:
> Hello all,
>
> "Liouville's polynomial identity" is given by
> http://mathworld.wolfram.com/LiouvillePolynomialIdentity.html and can
> be concisely encoded as,
>
> 6(x1^2 + x2^2 + x3^2 + x4^2)^2 = Sum(x_i +/- x_j)^4
>
> To determine the number of terms of the summation, since we are to
> choose 2 objects from 4, then this is Binomial[4,2] = 6. But as there
> are 2 sign changes, then total is 2 x 6 = 12 terms, given explicitly
> in the link above. Going higher, and choosing 3 objects out of n
> variables, I found that,
>
> 60(x1^2 + x2^2 + ... + x7^2)^2 = Sum(x_i +/- x_j +/- x_k)^4
>
> is true. The RHS contains 4 x 35 = 140 terms. (If the x_i are non-
> zero, one cannot express the square of the sum of less than 7 squares
> in a similar manner.)
>
> Question: If we take the next step,
>
> a(x1^2 + x2^2 + ... + x_n^2)^2 = Sum(x_i +/- x_j +/- x_k +/- x_m)^4
>
> for some positive integer "a", then what is the least n, if we are to
> choose 4 objects at a time out of the x_n?
>
> I believe the RHS is a simple matter for Mathematica to calculate, and
> one can incrementally test n = 5,6,7,...etc until a neat identity is
> found.
>
> - Titus
>
>
>
Regards,
Kurt Tekolste