Re: RSolve problem: won't solve convolution recurrence
- To: mathgroup at smc.vnet.net
- Subject: [mg106258] Re: [mg106224] RSolve problem: won't solve convolution recurrence
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Wed, 6 Jan 2010 06:01:28 -0500 (EST)
- Reply-to: hanlonr at cox.net
If you know the form, you can solve for the coefficients
Clear[f, g];
f[1] = 1;
f[x_Integer?Positive] :=
f[x] = Sum[f[i]*f[x - i], {i, 1, x - 1}]
g[x_Integer?Positive] :=
Product[(a*i + b)/(c*i + d), {i, 2, x}]
Reduce[Table[f[n] == g[n], {n, 2, 5}], {a, b, c, d}, Integers]
(Element[C[1], Integers] &&
C[1] >= 1 && a == 4*C[1] &&
b == -6*C[1] && c == C[1] &&
d == 0) || (Element[C[1],
Integers] && C[1] <= -1 &&
a == 4*C[1] && b == -6*C[1] &&
c == C[1] && d == 0)
Simplify[%, C[1] == 1] // ToRules
{a -> 4, b -> -6, c -> 1, d -> 0}
Bob Hanlon
---- Sam <sam.j.walke at gmail.com> wrote:
=============
I am using mathematica 7, and am trying to solve a recurrence relation
using the code below:
RSolve[{f[x] == Sum[f[i]*f[x - i], {i, 1, x - 1}], f[1] == 1}, f[x],
x]
but it gives me the RSolve::piarg error. I have found that the
solution for the above problem is in fact
f[x_] = Product[(4*i - 6)/i, {i, 2, x}]
so it is theoretically solveable, but doing this sort of thing by hand
is extremely error prone. Is there any way of solving this type of
problem with mathematica or is it necessary to do it by hand?