MathGroup Archive 2010

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: ScientificForm[], formating question

  • To: mathgroup at smc.vnet.net
  • Subject: [mg112872] Re: ScientificForm[], formating question
  • From: "David Park" <djmpark at comcast.net>
  • Date: Mon, 4 Oct 2010 06:06:48 -0400 (EDT)

Roll your own using MantissaExponent.

r1 = 0.087540;
r2 = 0.087549; 

sForm[r_] :=
 Module[{mantissa, exponent},
  {mantissa, exponent} = MantissaExponent[r];
  Row[
   {NumberForm[10 mantissa, {5, 4}, NumberPadding -> {"", "0"}],
    "E", exponent - 1}]
  ] 

sForm /@ {r1, r2} // Column 

8.7540E-2
8.7549E-2

NumberPadding on the right of the mantissa does not appear to work in
ScientificForm.


David Park
djmpark at comcast.net
http://home.comcast.net/~djmpark/  


From: Nasser M. Abbasi [mailto:nma at 12000.org] 

Mathematica experts:


I can't get ScientificForm[] to always show 4 digits to the right of
the decimal point.

Example:

n  = 0.087540;
m = 0.087549;

ScientificForm[Column[{n, m}], 5,  NumberFormat -> (Row[{#1, "E", #3}]
&)]


This prints like this:

8.754E-2
8.7549E-2

Which is correct, but I want it to display as

8.7540E-2
8.7549E-2

So that all numbers in the table has the same number of digits. so
'nicer' to look at.

The problem in this example, n has a zero at the last position, and so
is not shown (correctly), but I want 4 digits there.

I looked at all the options for ScientificForm and do not see how to
do it.

thanks
--Nasser





  • Prev by Date: Re: NMINIMIZATION WITH COMPLEX CONJUGATE
  • Next by Date: Re: NMINIMIZATION WITH COMPLEX CONJUGATE
  • Previous by thread: Re: ScientificForm[], formating question
  • Next by thread: Re: ScientificForm[], formating question