Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: How to interpolate vectors?

• To: mathgroup at smc.vnet.net
• Subject: [mg112909] Re: How to interpolate vectors?
• From: Patrick Scheibe <pscheibe at trm.uni-leipzig.de>
• Date: Tue, 5 Oct 2010 05:36:57 -0400 (EDT)
• References: <201010050704.DAA11542@smc.vnet.net>

Hi,

interpolate the x-values and the y-values separately and use the
two interpolating functions to create your resampling:

data = Table[{y, -x}, {x, -3, 3, 6/31.}, {y, -3, 3, 6/31.}];
Block[{ipx, ipy}, {ipx, ipy} = 
   ListInterpolation[#, {{-3, 3}, {-3, 3}}] & /@ 
    Transpose[data, {3, 2, 1}];
  datanew = 
   Table[Through[{ipx, ipy}[y, x]], {x, -3, 3, 6/7.}, {y, -3, 3, 
     6/7.}]];
ListLineIntegralConvolutionPlot[#, StreamStyle -> White, 
   StreamPoints -> 20, ColorFunction -> "AvocadoColors", 
   PlotLabel -> 
    Style["Dimension: " <> ToString[Dimensions[#]], Blue, 
     FontFamily -> "Helvetica"]] & /@ {data, datanew}


Cheers
Patrick

On Tue, 2010-10-05 at 03:04 -0400, Szymon Roziewski wrote:
> Hello there,
> Does anybody know how to interpolate vector data e.g. wind data?
> For example I have wind data on grid 448 columns and 615 rows and I need
> this on grid 132x145.
> Does Mathematica provide such a function or maybe someone has that.
> 
> 
> Kind regards
> Szymon Roziewski
> 
> 

• References:
  • How to interpolate vectors?
    • From: Szymon Roziewski <szymon.roziewski@gmail.com>