MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Why does Solve give me no solutions for this in Version 8.0.1?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg119969] Re: Why does Solve give me no solutions for this in Version 8.0.1?
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Sat, 2 Jul 2011 05:01:59 -0400 (EDT)

$Version

8.0 for Mac OS X x86 (64-bit) (February 23, 2011)

ClearAll[a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s];

vars={a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s};

eqns={
Total[vars]-190==0,
a+b+c-38==0,
a+d+h-38==0,
a+e+j+o+s-38==0,
b+e+i+m-38==0,
b+f+k+p-38==0,
c+f+j+n+q-38==0,
c+g+l-38==0,
d+e+f+g-38==0,
d+i+n+r-38==0,
g+k+o+r-38==0,
h+i+j+k+l-38==0,
h+m+q-38==0,
l+p+s-38==0,
m+n+o+p-38==0,
q+r+s-38==0};

soln1=Solve[eqns,vars][[1]]

Solve::svars: Equations may not give solutions for all "solve" variables. >>

{c->38-a-b,g->38-d-e-f,h->38-a-d,k->38-b-e-f-i-j,l->-38+a+b+d+e+f,m->38-b-e-i,n->38-d-e-f-i-j,o->-38+b+d+e+f+i,p->e+i+j,q->-38+a+b+d+e+i,r->e+f+j,s->76-a-b-d-2 e-f-i-j}

And@@(eqns/.soln1)

True

soln2=Reduce[eqns,vars]//ToRules

{c->38-a-b,g->38-d-e-f,h->38-a-d,k->38-b-e-f-i-j,l->-38+a+b+d+e+f,m->38-b-e-i,n->38-d-e-f-i-j,o->-38+b+d+e+f+i,p->e+i+j,q->-38+a+b+d+e+i,r->e+f+j,s->76-a-b-d-2 e-f-i-j}

soln1===soln2

True


Bob Hanlon

---- Phil J Taylor <xptaylor at gmail.com> wrote: 

=============
This system of equations for the Magic Hexagon is indeterminate.
 Solve still provides useful information in  Version 6.0

ClearAll[a, b, c, d, e, f, g, h, i, j, k, l, m, n, o, p, q, r, s];
eqns = {
   a + b + c + d + e + f + g + h + i + j + k + l + m + n + o + p + q + r + s
- 190 == 0,
   a + b + c - 38 == 0,
   a + d + h - 38 == 0,
   a + e + j + o + s - 38 == 0,
   b + e + i + m - 38 == 0,
   b + f + k + p - 38 == 0,
   c + f + j + n + q - 38 == 0,
   c + g + l - 38 == 0,
   d + e + f + g - 38 == 0,
   d + i + n + r - 38 == 0,
   g + k + o + r - 38 == 0,
   h + i + j + k + l - 38 == 0,
   h + m + q - 38 == 0,
   l + p + s - 38 == 0,
   m + n + o + p - 38 == 0,
   q + r + s - 38 == 0
   };

Join[
 Solve[eqns, b], Solve[eqns, d], Solve[eqns, g],
 Solve[eqns, m], Solve[eqns, p], Solve[eqns, j],
 Solve[eqns, r], Solve[eqns, e], Solve[eqns, f],
 Solve[eqns, i], Solve[eqns, k], Solve[eqns, n],
 Solve[eqns, o], Solve[eqns, a], Solve[eqns, c],
 Solve[eqns, h], Solve[eqns, l], Solve[eqns, q],
 Solve[eqns, s]]

Out[1]: {{b -> j + n + o}, {d -> j + k + o}, {g -> i + j + n},
 {m -> f + j + k}, {p -> e + i + j}, {j -> -38 + d + g + r},
 {r -> -38 + h + l + m + p}, {e -> -38 + h + k + q + r},
 {f -> -38 + i + l + r + s}, {i -> -38 + f + p + q + s},
 {k -> -38 + e + m + q + s}, {n -> -38 + g + h + k + l},
 {o -> -38 + d + h + i + l}, {a -> -38 + i + m + n + q + r},
 {c -> -38 + k + o + p + r + s}, {h -> -38 + n + o + p + r + s},
 {l -> -38 + m + n + o + q +  r}, {q -> -38 + g + k + l + o + p},
 {s -> -38 + d + h + i + m +  n}}

Version 8.0.1 returns {}.




  • Prev by Date: Re: Why does Solve give me no solutions for this in Version 8.0.1?
  • Next by Date: Re: Why does Solve give me no solutions for this in Version 8.0.1?
  • Previous by thread: Re: Why does Solve give me no solutions for this in Version 8.0.1?
  • Next by thread: Re: Why does Solve give me no solutions for this in Version 8.0.1?