MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Getting a chess with circles

  • To: mathgroup at smc.vnet.net
  • Subject: [mg119494] Re: Getting a chess with circles
  • From: Heike Gramberg <heike.gramberg at gmail.com>
  • Date: Mon, 6 Jun 2011 07:28:37 -0400 (EDT)

Is this what you had in mind?

chessboard[n_] := With[{C1 = {-n/2, 0}, C2 = {n/2, 0}},
  RegionPlot[
   Norm[{x, y} - C1] < n && Norm[{x, y} - C2] < n, {x, -n/2,
    n/2}, {y, -n, n},
   MeshFunctions -> {Norm[{#1, #2} - C1] &, Norm[{#1, #2} - C2] &},
   Mesh -> {Range[n], Range[n]},
   MeshShading -> {{Purple, Yellow}, {Yellow, Purple}},
   AspectRatio -> 2, Frame -> False,
   PlotPoints -> 20, BoundaryStyle -> Black
   ]]

chessboard[10]

Heike

On 6 Jun 2011, at 11:24, Jean-Louis Garcin wrote:

>
>
>
> Hello,
>
> In the features demonstrations  there is an example about  n-Player Chessboards.
>
> With this model we can get a chess for example:
> ParametricPlot[
> Table[{Re[E^(I Arg[(u + I v)^2]) Abs[(u + I v)] E^(I (j - 1) 2 Pi)],
>   Im[E^(I Arg[(u + I v)^2]) Abs[(u + I v)] E^(I (j - 1) 2 Pi)]}, {j, 1,
>   1}], {u, -1, 1}, {v, -1, 1}, MeshStyle -> {None, None}, Mesh -> {10, 4},
> MeshShading -> {{Yellow, Orange}, {Orange, Yellow}}, PlotRange -> 1.5,
> Axes -> False, Frame -> False, ImageSize -> {400, 400}]
>
>
> But I would want  to get a chess with  two lists of circles: the first list is made with circles which have the same center A , and  the second list is made with the same center B, A and B are different.
>
> For instance AB=10 the radius of the circles are 1, then 2, 3,  and son on.
>
> So the intersections point of circles are on ellipses or hyperbols.
>
>
> I have no idea.
>
> Thank You for your help.
>
> Jean-Louis Garcin
>
>
>
>


  • Prev by Date: Re: Mapping points
  • Next by Date: Re: How the final "typeset" expression of TableForm is generated?
  • Previous by thread: Getting a chess with circles
  • Next by thread: How show axes labels with AxesOrigin->{0,0,0} in 3D?