Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: System of differential equations

• To: mathgroup at smc.vnet.net
• Subject: [mg128987] Re: System of differential equations
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Fri, 7 Dec 2012 01:37:53 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-newout@smc.vnet.net
• Delivered-to: mathgroup-newsend@smc.vnet.net
• References: <20121206095813.308946374@smc.vnet.net>

The Sin functions must be entered as Sin vice sin. The range of t is
too large to be handled.

s = NDSolve[{
    ph1''[t] + ph1'[t] + Sin[ph1[t]] - mu[t] - mu'[t] == 0.005,
    ph2''[t] + ph2'[t] + Sin[ph2[t]] + mu[t] + mu'[t] == 0.005,
    0.2 mu'[t] + mu[t] == ph1'[t] - ph2'[t], ph2[0] == 0, ph1[0] == 0,
    ph2'[0] == 0, ph1'[0] == 0, mu[0] == 0},
   {ph1[t], ph2[t], mu[t]},
   {t, 0, 240}];

Plot[Evaluate[Tooltip[#, ToString[#]] & /@
    {ph1[t], ph2[t], mu[t]} /. s],
 {t, 0, 10},
 Frame -> True, Axes -> False]

However, the range on t affects the results

s = NDSolve[{
    ph1''[t] + ph1'[t] + Sin[ph1[t]] - mu[t] - mu'[t] == 0.005,
    ph2''[t] + ph2'[t] + Sin[ph2[t]] + mu[t] + mu'[t] == 0.005,
    0.2 mu'[t] + mu[t] == ph1'[t] - ph2'[t], ph2[0] == 0, ph1[0] == 0,
    ph2'[0] == 0, ph1'[0] == 0, mu[0] == 0},
   {ph1[t], ph2[t], mu[t]},
   {t, 0, 100}];

Plot[Evaluate[Tooltip[#, ToString[#]] & /@
    {ph1[t], ph2[t], mu[t]} /. s],
 {t, 0, 10},
 Frame -> True, Axes -> False]


Bob Hanlon


On Thu, Dec 6, 2012 at 4:58 AM,  <hazem.abdelhafiz at gmail.com> wrote:
> Dear all,
> I want to solve this system of equations but I always get an error
>
> NDSolve::ndnum:Encountered non-numerical value for a derivative at t==0
>
> can any one help me on this
>
> s=NDSolve[{
> ph1''[t]+ph1'[t]+sin[ph1[t]]-mu[t]-mu'[t]==0.005,
> ph2''[t]+ph2'[t]+sin[ph2[t]]+mu[t]+mu'[t]==0.005,
> 0.2mu'[t]+mu[t]==ph1'[t]-ph2'[t],
> ph2[0]==0,
> ph1[0]==0,
> ph2'[0]==0,
> ph1'[0]==0,
> mu[0]==0
> },
> {ph1[t],ph2[t],mu[t]},
> {t,0,5000}
> ]
>
> thanks in advance,
>

• References:
  • System of differential equations
    • From: hazem.abdelhafiz@gmail.com