MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Solid modeling using Manipulate

  • To: mathgroup at smc.vnet.net
  • Subject: [mg127156] Re: Solid modeling using Manipulate
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Mon, 2 Jul 2012 22:18:46 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • References: <201207020928.FAA13413@smc.vnet.net>

ThickCyl[a_, t_, v_] = {a Cos[t + v], 6 t/5, a Sin[t + v]};

Manipulate[
 Show[
  ParametricPlot3D[ThickCyl[a, t, v],
   {v, 0, 2 Pi}, {a, 1, 1.6}, Mesh -> {18, 4}],
  ParametricPlot3D[ThickCyl[a, t, v],
   {t, 0, 2 Pi}, {a, 1, 1.6}, Mesh -> {18, 4}],
  ParametricPlot3D[ThickCyl[a, t, v],
   {t, 0, 2 Pi}, {v, 0, 2 Pi}, Mesh -> {18, 18}],
  PlotRange -> {{-1.8, 1.8}, {-.25, 8}, {-1.8, 1.8}},
  ViewPoint -> {3, 1, 2}],
 {{a, 1, "Cylinder Expansion ( a )"}, 1, 1.6, .1,
  Appearance -> "Labeled"},
 {{t, 0, "Ring Slide ( t )"}, 0, 2 Pi, Pi/10,
  Appearance -> "Labeled"},
 {{v, 0, "Fin Rotation ( v }"}, 0, 2 Pi, Pi/10,
  Appearance -> "Labeled"},
 FrameLabel -> {{None, None},
   {StringForm["{x, y, z} = ``",
     TraditionalForm[ThickCyl["a", "t", "v"]]],
    "Thick Cylinder"}}]


Bob Hanlon


On Mon, Jul 2, 2012 at 5:28 AM, Narasimham <mathma18 at hotmail.com> wrote:
> ThickCyl[a_,t_,v_]={a Cos[t+v],1.2 t,a Sin[t+v]}; (* GLNarasimham
> SolidModelingThickCyl.nb *)
> Cyl=ParametricPlot3D[{Cos[t],u,Sin[t]},{t,0,2 Pi},{u,0,2 Pi},ViewPoint-
>>{3,1,2}]
> RingSlide=Manipulate[ParametricPlot3D[ThickCyl[a,t,v],{v,0,2 Pi},{a,
> 1,1.6},Mesh->{18,4},PlotRange->{{-1.8,1.8},{-.25,8},
> {-1.8,1.8}},ViewPoint->{3,1,2}],{t,0,2 Pi,Pi/10}]
> FinRotn=Manipulate[ParametricPlot3D[ThickCyl[a,t,v],{t,0,2 Pi},{a,
> 1,1.6},Mesh->{18,4},PlotRange->{{-1.8,1.8},{-.25,8},
> {-1.8,1.8}},ViewPoint->{3,1,2}],{v,0,2 Pi,Pi/10}]
> CylExpn=Manipulate[ParametricPlot3D[ThickCyl[a,t,v],{t,0,2 Pi},{v,0,2
> Pi},Mesh->{18,18},PlotRange->{{-1.8,1.8},{-0.25,8},
> {-1.8,1.8}},ViewPoint->{3,1,2}],{a,1,1.6,.1}]
>
> How to combine the above four graphics into a single dynamic image
> with t,v and a Manipulates ?
>
> Regards
> Narasimham



  • Prev by Date: Re: Numerical integration over an arbitrary 2D domain
  • Next by Date: Re: Rearranging terms - user-defined
  • Previous by thread: Solid modeling using Manipulate
  • Next by thread: Re: Solid modeling using Manipulate