Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Using CountryData to Get US Population by State

• To: mathgroup at smc.vnet.net
• Subject: [mg126757] Re: Using CountryData to Get US Population by State
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Tue, 5 Jun 2012 04:52:10 -0400 (EDT)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• References: <201206020944.FAA01148@smc.vnet.net>

statePopulationData =
  WolframAlpha[
   "population of states in the United States", \
{{"PropertyRanking:USStateData", 1}, "ComputableData"}];

statePopulations = Thread[
   statePopulationData[[All, 2]] ->
    statePopulationData[[All, 3]]];

maxPopulation = Max[statePopulationData[[All, 3]]];
minPopulation = Min[statePopulationData[[All, 3]]];

statePopulationRankings = Thread[
   statePopulationData[[All, 2]] ->
    statePopulationData[[All, 1]]];

usaMapData =
  Import["http://code.google.com/apis/kml/documentation/us_states.kml";,
    "Data"][[1]];

states = StringDrop[#, -7] & /@ ("PlacemarkNames" /. usaMapData);

statePolygons = Thread[states -> ("Geometry" /. usaMapData)];

color = ColorData["Temperature"];

stateGraphic[value_, poly_] :=
 GraphicsGroup[{EdgeForm[{Thin, Black}], FaceForm[color[value]], poly}]


Color by population ranking

Graphics[stateGraphic @@@
  ({1 - Rescale[#, {1, 50}] /.
       statePopulationRankings,
      # /. statePolygons} & /@
    states)]


Color by population

Graphics[stateGraphic @@@
  ({Rescale[#, {minPopulation, maxPopulation}] /.
            statePopulations,
      # /. statePolygons} & /@ states)]


Bob Hanlon


On Mon, Jun 4, 2012 at 4:20 AM, Hobbs, Sylvia (DPH)
<sylvia.hobbs at state.ma.us> wrote:
> or input in Mathematica = state population rankings
>
> too bad it doesn't automatically create a gradient map like is SAS or STATA.
>
> Sylvia D. Hobbs, MPH
>
> Director of Research & Evaluation
> Bureau of Health Care Safety and Quality
> Massachusetts Department of Public Health
> 99 Chauncy Street, 11th Floor
> Boston MA 02111
> ________________________________________
> From: Bob Hanlon [hanlonr357 at gmail.com]
> Sent: Sunday, June 03, 2012 4:02 PM
> To: mathgroup at smc.vnet.net
> Subject: Re: Using CountryData to Get US Population by State
>
> After closer comparison between the two results, my original approach
> provides erroneous results due to misinterpretation of names (e.g.,
> New York resulted in the population of New York City rather than New
> York State, Georgia resulted in Country of Georgia rather than US
> state of Georgia). So Harvey's approach is not only faster it is
> correct.
>
>
> Bob Hanlon
>
>
> On Sun, Jun 3, 2012 at 8:01 AM, Bob Hanlon <hanlonr357 at gmail.com> wrote:
>> Harvey's solution is much faster than mine. Here is his in detail
>>
>> (statePopulations = WolframAlpha[
>>    "population of states in the United States",
>>    {{"PropertyRanking:USStateData", 1},
>>     "ComputableData"}]) // Grid
>>
>>
>> Bob Hanlon
>>
>> On Sun, Jun 3, 2012 at 4:59 AM, Harvey P. Dale <hpd1 at nyu.edu> wrote:
>>>        You could submit this query to WolframAlpha: "population of
>>> states in the United States"
>>>        Best,
>>>        Harvey
>>>
>>> -----Original Message-----
>>> From: Gregory Lypny [mailto:GREGORY.LYPNY at videotron.ca]
>>> Sent: Saturday, June 02, 2012 5:45 AM
>>> To: mathgroup at smc.vnet.net
>>> Subject: Using CountryData to Get US Population by State
>>>
>>> Hello everyone,
>>>
>>> Can anyone help me with the syntax for CountryData so that I can get the
>>> population of individual US states?
>>>
>>> Regards,
>>>
>>> Gregory

• References:
  • Using CountryData to Get US Population by State
    • From: Gregory Lypny <GREGORY.LYPNY@videotron.ca>