Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Eigenvalue and eigenvectors of a 10x10 matrix

• To: mathgroup at smc.vnet.net
• Subject: [mg128080] Re: Eigenvalue and eigenvectors of a 10x10 matrix
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Fri, 14 Sep 2012 00:23:15 -0400 (EDT)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-newout@smc.vnet.net
• Delivered-to: mathgroup-newsend@smc.vnet.net
• References: <20120913073743.F312F6764@smc.vnet.net>

mat = {
   {0, 1, 0, 0, 0, 0, 0, 0, 0, 0},
   {-(1 + K + K1), -0.1, K, 0, 0, 0, 0, 0, K1, 0},
   {0, 0, 0, 1, 0, 0, 0, 0, 0, 0},
   {K, 0, -(1 + 2 K + K1), -0.1, K, 0, 0, 0, K1, 0},
   {0, 0, 0, 0, 0, 1, 0, 0, 0, 0},
   {0, 0, K, 0, -(1 + 2 K + K1), -0.1, K, 0, K1, 0},
   {0, 0, 0, 0, 0, 0, 0, 1, 0, 0},
   {0, 0, 0, 0, K, 0, -(1 + K + K1), -0.1, K1, 0},
   {0, 0, 0, 0, 0, 0, 0, 0, 0, 1},
   {K1, 0, K1, 0, K1, 0, K1, 0, -(1 + 4 K1), -0.1}};

Rationalize the matrix first and you will get radicals rather than Root objects.

ev1 = Eigenvalues[Rationalize[mat]] // Simplify

{(1/20)*I*(I + Sqrt[399]), (-(1/20))*I*(-I + Sqrt[399]),
   (1/20)*(-1 - Sqrt[-399 - 2000*K1]),
   (1/20)*(-1 + Sqrt[-399 - 2000*K1]),
   (1/20)*(-1 - Sqrt[-399 - 800*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 - 800*K - 400*K1]),
   (1/20)*(-1 - Sqrt[-399 - 400*(2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 - 400*(2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 - Sqrt[-399 + 400*(-2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 + 400*(-2 + Sqrt[2])*K - 400*K1])}

Alternatively,

ev2 = Eigenvalues[mat] // Rationalize // ToRadicals // Simplify

{(1/20)*(-1 - Sqrt[-399 + 400*(-2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 + 400*(-2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 - Sqrt[-399 - 400*(2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 - 400*(2 + Sqrt[2])*K - 400*K1]),
   (1/20)*(-1 - Sqrt[-399 - 2000*K1]),
   (1/20)*(-1 + Sqrt[-399 - 2000*K1]),
   (1/20)*(-1 - Sqrt[-399 - 800*K - 400*K1]),
   (1/20)*(-1 + Sqrt[-399 - 800*K - 400*K1]),
   (-(1/20))*I*(-I + Sqrt[399]), (1/20)*I*(I + Sqrt[399])}

Sort[ev1] === Sort[ev2]

True

To learn about Root objects see
http://reference.wolfram.com/mathematica/ref/Root.html



Bob Hanlon


On Thu, Sep 13, 2012 at 3:37 AM, Redeemed <cakpovo at gmail.com> wrote:
> I want to do the eigen analysis of the matrix below
> mat := {{0, 1, 0, 0, 0, 0, 0, 0, 0, 0}, {-(1 + K + K1), -0.1, K, 0, 0,
>      0, 0, 0, K1, 0},
>    {0, 0, 0, 1, 0, 0, 0, 0, 0, 0}, {K, 0, -(1 + 2 K + K1), -0.1, K, 0,
>      0, 0, K1, 0},
>    {0, 0, 0, 0, 0, 1, 0, 0, 0, 0}, {0, 0, K, 0, -(1 + 2 K + K1), -0.1,
>      K, 0, K1, 0},
>    {0, 0, 0, 0, 0, 0, 0, 1, 0, 0}, {0, 0, 0, 0, K,
>     0, -(1 + K + K1), -0.1, K1, 0},
>    {0, 0, 0, 0, 0, 0, 0, 0, 0, 1}, {K1, 0, K1, 0, K1, 0, K1,
>     0, -(1 + 4 K1), -0.1}};
>
> I kept getting a long solution with some Root [] and #1
> I do not know what I am doing wrong
> Any help,
> Its very urgent
>
> Thanks
>

• References:
  • Eigenvalue and eigenvectors of a 10x10 matrix
    • From: Redeemed <cakpovo@gmail.com>