MathGroup Archive 2013

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Limiting Output Based on Z Axis of Plotd3d[Evaluate@Table[PDF[NormalDistribution

  • To: mathgroup at smc.vnet.net
  • Subject: [mg130540] Re: Limiting Output Based on Z Axis of Plotd3d[Evaluate@Table[PDF[NormalDistribution
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Sat, 20 Apr 2013 05:41:49 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net
  • References: <20130419051847.3257B6B48@smc.vnet.net>

Since you refer to x, y, and z; presumably you mean a binormal rather than
a normal distribution.


max = 2.25;
zMax = 35;


Manipulate[
 ContourPlot[
  200*
   PDF[BinormalDistribution[0], {x, y}],
  {x, -max, max}, {y, -max, max},
  Contours -> Range[step, zMax, step],
  ContourShading -> None,
  ContourStyle -> Thick],
 {{step, 10, "Contour Step Size"}, {2.5, 5, 10}}]


Manipulate[
 Plot3D[
  200*
   PDF[BinormalDistribution[0], {x, y}],
  {x, -max, max}, {y, -max, max},
  MeshFunctions -> {#3 &},
  Mesh -> {Range[step, zMax, step]},
  PlotStyle -> Opacity[opac]],
 {{step, 10, "Contour Step Size"}, {2.5, 5, 10}},
 {{opac, 0.5, "PDF Opacity"}, 0, 1, .1,
  Appearance -> "Labeled"}]


Bob Hanlon


On Fri, Apr 19, 2013 at 1:18 AM, Garrett Fisher <fisher.garrett at gmail.com>wrote:

> Good Day,
>
> I am plotting some bell curves using the function in the subject line.
> The PDF of NormalDist produces static Z values - which is fine -
> except I wish to limit them. I would like to show XY data at Z 0, 10,
> 20, 30 and so forth - with an intended gap in the Plot for Z 1-9,
> 11-19, 21-29. I am beginning to think that getting into the actual
> data output of the Table might be necessary. I am fine with that - I
> am just a bit new at Mathematica - so I don't know where to start to
> figure that part out.
>
> Thanks for any help!!!
>
>


  • Prev by Date: Re: Converting a magnified image of a line to a single pixel smoothed
  • Next by Date: Re: Limiting Output Based on Z Axis of Plotd3d[Evaluate@Table[PDF[NormalDistribution
  • Previous by thread: Limiting Output Based on Z Axis of Plotd3d[Evaluate@Table[PDF[NormalDistribution
  • Next by thread: Re: Limiting Output Based on Z Axis of Plotd3d[Evaluate@Table[PDF[NormalDistribution