MathGroup Archive: July 2013 [00137]

[Date Index] [Thread Index] [Author Index]

Re: Export Import Array

To: mathgroup at smc.vnet.net
Subject: [mg131390] Re: Export Import Array
From: Bob Hanlon <hanlonr357 at gmail.com>
Date: Thu, 18 Jul 2013 02:59:27 -0400 (EDT)
Delivered-to: l-mathgroup@mail-archive0.wolfram.com
Delivered-to: l-mathgroup@wolfram.com
Delivered-to: mathgroup-outx@smc.vnet.net
Delivered-to: mathgroup-newsendx@smc.vnet.net
References: <20130717055004.0214169C9@smc.vnet.net>

One way:

steps = {.05, .1, .2, .25};


{dx, dy, dz} = Table[RandomChoice[steps], {3}]


{0.2, 0.05, 0.1}


vectors = Table[{x, y, z},
   {x, -1, 1, dx},
   {y, -1, 1, dy},
   {z, -1, 1, dz}];


dim = Dimensions[vectors]


{11, 41, 21, 3}


Export["vectors.csv", Flatten[vectors, 2]];


vectors2 = Fold[Partition[#1, #2] &,
   Import["vectors.csv"],
   dim // Most // Rest // Reverse];


vectors == vectors2


True



Bob Hanlon




On Wed, Jul 17, 2013 at 1:50 AM, graser <graser at gmail.com> wrote:

> Dear Mathematica Users!
>
> I have a question for you about Exporting and Importing array.
> Let's say there is a array (or vector) like,
> vectors =
>   Table[{x, y, z}, {x, -1, 1, .25}, {y, -1, 1, .25}, {z, -1, 1, .25}];
>
> If I export vectors as "XLS" format and import the XLS file,
> TT= Import["vector.xls", "XLS"];
>
> Some funny thing happen like
> TT[[1, 1, 1]] should be {-1,-1,-1} so that If I do TT[[1, 1, 1,1]] , it
> should give -1.
>
> But instead of that, TT[[1, 1, 1]]  gives a string as "{-1., -1., -1.}" .
>
> If I export vectors as "Table" format and import the table file,
> TR= Import["vector.data", "Table"];
> It gives  something like.. {"{{-1.,", "-1.,", "-1.},",....  All double
> comma.
>
>
> Do you know how to properly export vector (or array) ?
>
> And if I import string instead of vecotor like TT, How to convert TT like
> string to array?
> "{-1., -1., -1.}"  -> {-1,-1,-1}
>
> Thanks!
>
>
>
>