Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Noob requests help with recursive formula

• To: mathgroup at smc.vnet.net
• Subject: [mg130147] Re: Noob requests help with recursive formula
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Thu, 14 Mar 2013 07:14:30 -0400 (EDT)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-newout@smc.vnet.net
• Delivered-to: mathgroup-newsend@smc.vnet.net
• References: <20130313081908.8485769BB@smc.vnet.net>

g[a_?VectorQ, b_?VectorQ] := Module[
   {c, n = Length[a]},
   c = Table[0, {n}];
   Table[c[[k]] =
     f[a[[k]]/(b[[k]] - Total[
          a[[1 ;; k - 1]]/c[[1 ;; k - 1]]])],
    {k, n}];
   c] /; Length[a] == Length[b]

Clear[a, b, f];

c = With[{n = 3}, g[Array[a, n], Array[b, n]]]

{f[a[1]/b[1]], f[a[2]/(b[2] - a[1]/f[a[1]/b[1]])],
   f[a[3]/(b[3] - a[1]/f[a[1]/b[1]] -
          a[2]/f[a[2]/(b[2] - a[1]/f[a[1]/b[1]])])]}

f[x_] = x;

a = RandomReal[1, 10];
b = RandomReal[1, 10];

c = g[a, b]

{1.67559, 1.14738, -1.68319, -3.93066, -1.94426, 0.996524, -1.32233, \
0.339927, -1.09966, 1.12554}


Bob Hanlon


On Wed, Mar 13, 2013 at 4:19 AM,  <Garcia5529 at yahoo.fr> wrote:
> I appreciate any tips on how to code this in Mathematica.
> I have two lists, each with 99 elements; A and B. Real numbers.
> I want to form a list, C, whose elements are functions (F[]) of A and B, and also previous elements of C itself.
>
> C ={F[A1/B1], F[A2/(B2-A1/C1)], F[A3/(B3-A1/C1-A2/C2)],..F[A99/(B99-A1/C1...-A98/C98.)}
>
> ...where the integers after A,B, and C, are element indices.
> Thanks for any suggestions.
> HG
>

• References:
  • Noob requests help with recursive formula
    • From: Garcia5529@yahoo.fr