MathGroup Archive 1995

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Numerical evaluation of HypergeometricPFQ[{a,b,c},{d,e},1]

  • To: mathgroup at christensen.cybernetics.net
  • Subject: [mg512] Re: [mg497] Numerical evaluation of HypergeometricPFQ[{a,b,c},{d,e},1]
  • From: bob Hanlon <hanlon at pafosu2.hq.af.mil>
  • Date: Mon, 6 Mar 1995 19:29:21

In my earlier post I was careless and left off a Sign[u] factor in dealing
with the even integers.  This would result in a sign error for negative
even integers.  I concluded that the easiest way to deal with the negative
integers is to use the negative symmetry of the Sin function for all
negative values.  I also made a few other minor changes.

Bob Hanlon

___________

theIntegral::usage = "theIntegral[u] is the integral of
	Sin[u t]/Sin[t] on the interval [0, Pi/2].";

theIntegral[ u_?Negative ] := - theIntegral[ -u ];
	(*  Sin[u t] has negative symmetry  *)

theIntegral[ u_ /; IntegerQ[(u - 1)/2] ] := Pi/2;
	(*  General expression is indeterminate for odd integers.  *)
	(*  Odd intgers:  Gradshteyn & Ryzhik, 3.612.3             *)

theIntegral[ u_ /; IntegerQ[u/2] ] := 
	2 Sum[(-1)^(k-1) / (2k - 1), {k, u/2}];
	(*  Provides exact numeric results for even integers.  *)
	(*  Even integers:  Gradshteyn & Ryzhik, 3.612.4       *)

theIntegral[ u_ /; Chop[u - Round[u]] == 0 ] := theIntegral[ Round[u] ];  
	(*  use integers for their real equivalents  *)

theIntegral[ u_ ] := Cos[u Pi/2] (- PolyGamma[(1 - u)/4] +
	PolyGamma[(3 - u)/4] + PolyGamma[(1 + u)/4] - 
	PolyGamma[(3 + u)/4]) / 4;
	(*  PolyGamma[z] = PolyGamma[0, z] is the digamma function,  *)
	(*  that is, logarithmic derivative of the gamma function.   *)


On Sun, 5 Mar 1995, bob Hanlon wrote:

> The specific result (Integrate[Sin[u t]/Sin[t], {t, 0, Pi/2}]) is given below.
> 
> 
> Bob Hanlon
> hanlon at pafosu2.hq.af.mil
> ____________________
> 
> Integrate[Sin[u t]/Sin[t], {t, 0, Pi/2}] // Simplify
> 
>       Pi u                     1          3 - u  3 + u
> u Cos[----] HypergeometricPFQ[{-, 1, 1}, {-----, -----}, 1]
>        2                       2            2      2
> -----------------------------------------------------------
>                                2
>                           1 - u
> 
> Clear[iss];
> 
> iss::usage = "iss[u] evaluates the integral: \n
> 	Integrate[Sin[u t]/Sin[t], {t, 0, Pi/2}]";
> 
> iss[ u_ /; u == 0 ] = 0;
> 
> iss[ u_ /; IntegerQ[(u - 1)/2] ] := Pi/2 Sign[u];  
> 	(*  general expression is indeterminate for odd integers  *)
> 	(*  Gradshteyn & Ryzhik, 3.612.3  *)
> 
> iss[ u_ /; IntegerQ[u/2] ] := 2 Sum[(-1)^(k-1) / (2k - 1), 
> 	{k, u/2 Sign[u]}];    (*  Gradshteyn & Ryzhik, 3.612.4  *)
> 
> iss[ u_ ] := - Cos[u Pi/2] (PolyGamma[(1 - u)/4] -
> 	PolyGamma[(3 - u)/4] - PolyGamma[(1 + u)/4] + 
> 	PolyGamma[(3 + u)/4]) / 4;
> 	(*  PolyGamma[z] = PolyGamma[0, z] is the digamma function,
> 	that is, the logarithmic derivative of the gamma function  *)
> 
> Plot[{iss[u], Pi/2 Sign[u]}, {u, -5, 11}];
> 
> _______________
> 
> > On Wed, 1 Mar 1995, NELSON M. BLACHMAN wrote:
> > 
> > >   This is a postscript to my 26 February message (reproduced below) 
> > > complaining about Mma's not giving a numerical value for 
> > > HypergeometricPFQ[{1/2,1,1},{1.45,1.55},1].  
> > > 
> > >   I've since found that Mma does evaluate things like 
> > > HypergeometricPFQ[{1/2,1,1},{1.4,1.6},0.99999],  but it takes 
> > > something like an hour on my 486DX33 PC--and it takes longer 
> > > and longer as the last argument gets closer and closer to 1.  
> > > So it's good that Mma quickly announces its inability to 
> > > compute  HypergeometricPFQ[{1/2,1,1},{1.4,1.6},1].  
> > > 
> > >   A different method is evidently needed when the last argument is 
> > > 1--provided that the sum of the components of the middle argument 
> > > exceeds the sum of the components of the first argument.  (If not, 
> > > the hypergeometric function seems likely to be infinite.)  So I 
> > > continue to hope for a formula for  3F2[{a,b,c},{d,e},1]  as a 
> > > ratio of products of gamma functions of (e, f, and e + f minus 
> > > 0, a, b, c, a + b, etc.), though I've so far been unable to 
> > > devise a satisfactory conjecture of this sort.
> > > 
> > > 						Nelson M. Blachman
> > > 
> > > 
> > > >From:	GTEWD::BLACHMAN     "NELSON M. BLACHMAN" 26-FEB-1995 23:54:14.57
> > > >To:	MX%"mathgroup at christensen.cybernetics.net"
> > > >CC:	BLACHMAN
> > > >Subj:	Numerical Evaluation of HypergeometricPFQ
> > > 
> > >   I was pleased to see just now that Mma's able to evaluate 
> > > Integrate[Sin[t u]/Sin[t],{t,0,Pi/2}]  in terms of HypergeomtricPFQ.  
> > > When I asked it to plot the result, however, I found it apparently 
> > > unable to determine numerical values for HypergeomtricPFQ.  
> > > 
> > >   Maple can sometimes compute numerical values for HypergeomtricPFQ, 
> > > but for the particular denominator indices here it complains of 
> > > iteration limits' being exceeded.  Does anyone know of a way to 
> > > get Mma 2.2 to evaluate HypergeomtricPFQ numerically?
> > > 
> > >   I suspect there's a simple expression for HypergeomtricPFQ[{ },{ },1] 
> > > in terms of gamma functions when  P = Q + 1;  there is, anyhow, if  
> > > P = 2  and  Q = 1.  Does anyone know if that's true and, if so, what 
> > > it is?
> > > 					Nelson M. Blachman
> > > 					GTE Government Systems Corp.
> > > 					Mountain View, California
> > > 
> > > Mathematica 2.2 for DOS 387
> > > Copyright 1988-93 Wolfram Research, Inc.
> > > 
> > > In[1]:= Integrate[Sin[t u]/Sin[t],{t,0,Pi/2}]
> > > 
> > >          3   u        Pi u                     1          3 - u  3 + u
> > >         (- + -) u Cos[----] HypergeometricPFQ[{-, 1, 1}, {-----, -----}, 1]
> > >          2   2         2                       2            2      2
> > > Out[1]= -------------------------------------------------------------------
> > >                                3    u     1    u   1   u
> > >                           4 (-(-) - -) (-(-) - -) (- - -)
> > >                                2    2     2    2   2   2
> > > 
> > > In[2]:= f[t_]:= %1 /. u -> t     Simplify ELIMINATES THE FIRST FACTOR IN 
> > > 				 THE NUMERATOR AND IN THE DENOMINATOR.  
> > > In[3]:= f[.1] // N
> > > 
> > > Out[3]= 0.0997665 HypergeometricPFQ[{0.5, 1., 1.}, {1.45, 1.55}, 1.]
> > > 
> > > 
> > 
> > 
> 
> 





  • Prev by Date: Re: any better to apply a function to second column?
  • Next by Date: Re: auto notebook running
  • Previous by thread: Re: Numerical evaluation of HypergeometricPFQ[{a,b,c},{d,e},1]
  • Next by thread: Numerical Evaluation of HypergeometricPFQ