Re: ODE
- To: mathgroup at smc.vnet.net
- Subject: [mg14532] Re: ODE
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Thu, 29 Oct 1998 04:33:28 -0500
- Organization: University of Western Australia
- References: <70rapb$sg7@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
Ing. Alessandro Toscano Dr. wrote:
> I found that the ODE:
>
> (A+B*x)*y(x) - y'(x)/y + y''(x)=0
>
> has an analytical, series solution near a regular singular point.
>
> Is there any package or notebook which solves ODE in terms of the so
> called series solutions?
As a concrete example, consider the Bessel differential equation:
In[1]:= beseqn = x^2 y''[x] + x y'[x] + (x^2 - n^2) y[x]
The point x=0 is a regular singular point. You can use the indicial
equation to determine the exponents of the singularity:
In[2]:= beseqn /. y -> Function[x, a[k]*x^k] In[3]:= Collect[%, x,
Factor]
In[4]:= Simplify[% /.
(c_.) a[k] x^(k + (m_.)) ->
(c a[k] x^(k + m) /. k -> k - m)]
We now have the indicial equation which has roots k = +/-n. Now we can
determine the series solution. First we simplify the differential
equation:
In[5]:= Simplify[beseqn/x^n /. y -> Function[{x}, x^n g[x]]]
Then we expand into a series (g[0] -> 1 without loss of generality)
In[6]:= % + O[x]^7 /. g[0] -> 1
and solve for the undetermined coefficients:
In[7]:= Solve[% == 0, Union[Cases[%, Derivative[_][g][_], Infinity]]]
Here is the resulting series expansion:
In[8]:= x^n (g[x] + O[x]^7 /. g[0] -> 1 /. First[%])
which can be compared with the built-in series:
In[9]:= FunctionExpand[Gamma[n + 1] 2^n * Series[BesselJ[n, x], {x, 0,
7}]]
Cheers,
Paul
____________________________________________________________________
Paul Abbott Phone: +61-8-9380-2734
Department of Physics Fax: +61-8-9380-1014
The University of Western Australia Nedlands WA 6907
mailto:paul at physics.uwa.edu.au AUSTRALIA
http://www.physics.uwa.edu.au/~paul
God IS a weakly left-handed dice player
____________________________________________________________________