Re: Summation without Mathematica
- To: mathgroup at smc.vnet.net
- Subject: [mg27440] Re: [mg27416] Summation without Mathematica
- From: BobHanlon at aol.com
- Date: Sun, 25 Feb 2001 20:55:44 -0500 (EST)
- Sender: owner-wri-mathgroup at wolfram.com
You can simplify the problem by generalizing the problem (make it harder).
First let
Mathematica solve the problem so we have an answer to check against.
soln = Sum[x^3 * (7/8)^x, {x, 1, Infinity}]
18872
A more general form of the problem is
genSoln = Sum[x^3 * y^x, {x, 1, Infinity}]//Simplify
(y*(y^2 + 4*y + 1))/(y - 1)^4
Verifying this for the case at hand,
(genSoln /. y -> 7/8) == soln
True
An easy way to derive the general result is by using the differential
operator y*D[#, y]&
y*D[y^x, y] == (y*D[#, y]& [y^x]) == x*y^x
True
Applying the operator three times,
Nest[y*D[#, y]&, y^x, 3] == y*D[y*D[y*D[y^x, y], y], y] == x^3 * y^x
True
Substituting and pulling the operator outside the summation,
Sum[y^x, {x, 1, Infinity}]
-(y/(y - 1))
Application of the differential operator to this sum gives the desired result
Simplify[Nest[y*D[#, y]&, %, 3]] == genSoln
True
Bob Hanlon
In a message dated 2001/2/25 1:08:56 AM, mor3752 at alltel.net writes:
>Can someone help me to evaluate the sum from x=1 to infinity for the
>expression x^3(7/8)^x. I know the formulas that will evaluate either alone.
>But the product is giving me difficulty.