Re: Simplifying expression involving Log and I
- To: mathgroup at smc.vnet.net
- Subject: [mg38032] Re: Simplifying expression involving Log and I
- From: "Allan Hayes" <hay at haystack.demon.co.uk>
- Date: Tue, 26 Nov 2002 00:50:11 -0500 (EST)
- References: <arsit4$ef4$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
Dave we have,
e = d*Pi + I*d*(Log[M] - 2*Log[(-I)*Sqrt[(M*r)/d] +
Sqrt[M - (M*r)/d]]);
e2 = ComplexExpand[e, TargetFunctions -> {Re, Im}];
e3 = Simplify[e2, M > 0 && 0 < r < d]
d*(Pi + 2*ArcTan[Sqrt[M - (M*r)/d], -Sqrt[(M*r)/d]])
e4 = Simplify[e3, M > 0 && 0 < r < d,
ComplexityFunction -> (Count[#1, M, Infinity] & )]
d*(Pi - 2*ArcTan[Sqrt[r]/Sqrt[d - r]])
Here I have to be interactive:
a = ArcTan[Sqrt[r]/Sqrt[d - r]] is in (0, Pi/2),.
So b = Pi - 2a is in (0,Pi).
Consequently b/2 is ArcCos[Cos[b/2]].
That is
FullSimplify[Cos[(Pi - 2*ArcTan[Sqrt[r]/Sqrt[d - r]])/2],
0 < r < d]
1/Sqrt[d/r]
--
Allan
---------------------
Allan Hayes
Mathematica Training and Consulting
Leicester UK
www.haystack.demon.co.uk
hay at haystack.demon.co.uk
Voice: +44 (0)116 271 4198
Fax: +44 (0)870 164 0565
"Dave Snead" <dsnead6 at charter.net> wrote in message
news:arsit4$ef4$1 at smc.vnet.net...
> Hi,
>
> I'm trying to simplify (M, r, d are positive reals with r<d)
> d*Pi + I*d*(Log[M] - 2*Log[(-I)*Sqrt[(M*r)/d] + Sqrt[M - (M*r)/d]])
>
> to
>
> 2*d*ArcCos[Sqrt[r/d]]
>
> I've tried applying
>
> FullSimplify[#,M>0 && 0<r<d]&
>
> and
>
> ExpToTrig
>
> but Mathematica won't get rid of the Log and the I and give me the ArcCos.
>
> Does anyone know which Mathematica functions to apply to my expression to
> give me the simplification I want?
>
> Thanks in advance.
>
>
>
>
>