Re: fixed point _convergence _check
- To: mathgroup at smc.vnet.net
- Subject: [mg47502] Re: fixed point _convergence _check
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Wed, 14 Apr 2004 07:17:11 -0400 (EDT)
- Organization: The University of Western Australia
- References: <c537go$j52$1@smc.vnet.net> <c5gflm$ao7$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
In article <c5gflm$ao7$1 at smc.vnet.net>, m004202002 at yahoo.com (why)
wrote:
> In fixed point methodes to find out
> convergence we need to check
>
> [nonlinear system...
> u(x,y)=x^2+xy-10 = 0
> v(x,y)=y+3xy^2-57 = 0
> ]
>
> du/dx+dV/dx < 1 d<-means partial derivative
> and
> du/dy+dV/dy < 1
>
> means, after find out jacobian ,mathematica
> will inserts x,y value into du/dx,dV/dx,du/dy,dV/dy
> and show me du/dx+dV/dx =? ,du/dy+dV/dy=?
> how i can do that with mathematica ?
Not sure if I completely understand your question. Here goes anyway:
Here is your nonlinear system. Note that space implies multiplication:
u[x_, y_] = x^2 + x y - 10;
v[x_, y_] = 3 x y^2 + y - 57;
You can solve this system using Solve or NSolve:
Solve[{u[x, y], v[x, y]}=={0,0},{x,y}]
Alternatively, you can find the roots of this system using FindRoot
(effectively fixed points of Newton's method), specifiying a starting
point for the search:
ans = FindRoot[{u[x, y], v[x, y]}, {{x, 0}, {y, 1}}]
{x -> 2., y -> 3.}
Substituting (using /.) this solution into the conditions shows that
neither is satisfied:
D[u[x, y] + v[x, y], x] < 1 /. ans
False
D[u[x, y] + v[x, y], y] < 1 /. ans
False
Alternatively, compute the Jacobian,
jac = Outer[D, {u[x, y], v[x, y]}, {x, y}]
{{2 x + y, x}, {3 y^2, 6 x y + 1}}
and then test the conditions:
Thread[Plus @@ Transpose[jac] < 1] /. ans
{False, False}
Cheers,
Paul
--
Paul Abbott Phone: +61 8 9380 2734
School of Physics, M013 Fax: +61 8 9380 1014
The University of Western Australia (CRICOS Provider No 00126G)
35 Stirling Highway
Crawley WA 6009 mailto:paul at physics.uwa.edu.au
AUSTRALIA http://physics.uwa.edu.au/~paul