Re: Intra functional relations
- To: mathgroup at smc.vnet.net
- Subject: [mg47543] Re: [mg47493] Intra functional relations
- From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
- Date: Thu, 15 Apr 2004 03:40:50 -0400 (EDT)
- References: <200404141116.HAA27283@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
On 14 Apr 2004, at 20:16, Narasimham G.L. wrote:
> This may be almost frivolous: If f[x_]+f[y_]=f[x*y],then,
> can Mathematica prove or solve f[x_]= C Log[x],( C arbitrary constant)
> ?
> Also, if g[x_+y_]=g[x]*Sqrt[1- g[y]^2] + Sqrt[1- g[x]^2]*g[y],then,
> can it be proved that g[x_]=Sin[x]? Can the function capabilities of
> Mathematica in some way be put to use here? Regards.
>
>
I hope you do not expect Mathematica to do any proving by itself? But
if you mean whether it can be helpful in proving things of this kind
then the answer is certainly. I will just indicate what can be done in
your second case (the first is much easier).
But first of all, both your statements are not true without additional
conditions on the function g. For example, if the first rule is to hold
for all x than there is no solution at all. And in the second case,
g[x]=0 for all x is at least one other solution. Besides, even the
solution you are thinking of is g[x]:= Sin[ c x], where c is any
constant.
So you certainly need more assumptions on g. But anyway, this is
essentially how one can try to solve such problems:
The idea is to define a function of two variables:
In[1]:=
h[x_, y_] := g[x + y] - (g[y]*Sqrt[1 - g[x]^2] +
g[x]*Sqrt[1 - g[y]^2])
and then use the fact that h[x,y] is identically zero to obtain
information about g. The first thing to do is to find the value of
g[0]. We can do it as follows:
Solve[{h[0, 0] == 0}, g[0]]
{{g[0] -> 0}, {g[0] -> -(Sqrt[3]/2)}, {g[0] -> Sqrt[3]/2}}
This gives three possible values. With additional assumptions on g one
can eliminate the last two but I shall leave it to you ;-) So let's
consider only the case
g[0]=0;
We now use differentiation and obtain a differential equation:
eq = (D[h[x, y], y] /. y -> 0 /. Derivative[1][g][0] -> c) == 0
(-c)*Sqrt[1 - g[x]^2] + Derivative[1][g][x] == 0
(I had to substitute some other symbol, I chose c, for
Derivative[1][g][0] since its presence would interfere with the next
step).
We need also to remove the definition g[0]=0 to be able to use it in
the differential equation, so:
g[0] =.
Now we get our answer:
DSolve[{eq,g[0]==0},g[x],x]
Inverse functions are
being used by
Solve so some solutions may not be found; use Reduce for complete
\
solution information.
{{g[x]->Sin[c x]}}
Andrzej Kozlowski
Chiba, Japan
http://www.mimuw.edu.pl/~akoz/
- References:
- Intra functional relations
- From: mathma18@hotmail.com (Narasimham G.L.)
- Intra functional relations