Re: Problem with function
- To: mathgroup at smc.vnet.net
- Subject: [mg48318] Re: [mg48306] Problem with function
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Mon, 24 May 2004 00:45:12 -0400 (EDT)
- Reply-to: hanlonr at cox.net
- Sender: owner-wri-mathgroup at wolfram.com
I assume that the function is intended to be zero outside of the defined
region. Then using UnitStep to define g[t]
g[t_] := t*UnitStep[t]+3(1-t)/2*UnitStep[t-1]-(3-t)/2*UnitStep[t-3];
Plot[g[t], {t,-1,4}, PlotRange->All];
Simplify[g[t], t<0]
0
Simplify[g[t], 0<=t<1]
t
Simplify[g[t], 1<=t<3]//Expand//N
1.5 - 0.5*t
Simplify[g[t], 3<=t]
0
Taking the inverse transform of the Fourier transform will provide an
equivalent but simpler expression for g[t]
g2[t_] := Evaluate[
InverseFourierTransform[
FourierTransform[g[t], t, w],w,t]];
g2[t]
(1/4)*((t - 3)*Sign[t - 3] - 3*(t - 1)*Sign[t - 1] +
2*t*Sign[t])
Plot[g2[t],{t,-1,4}, PlotRange->All];
Simplify[g2[t], t<0]
0
FullSimplify[g2[t], 0<=t<1]
t
FullSimplify[g2[t], 1<=t<3]//Expand//N
1.5 - 0.5*t
FullSimplify[g2[t], 3<=t]
0
The Fourier transform is then
FourierTransform[g2[t], t, w]//InputForm
-((-1 + E^(I*w))^2*(2 + E^(I*w)))/(2*Sqrt[2*Pi]*w^2)
InverseFourierTransform[%,w,t]==g2[t]
True
Bob Hanlon
>
> From: "DJkapi" <djkapi at poczta.onet.pl>
To: mathgroup at smc.vnet.net
> Date: 2004/05/23 Sun AM 06:15:34 EDT
> To: mathgroup at smc.vnet.net
> Subject: [mg48318] [mg48306] Problem with function
>
> How to compute in Mathematica fourier transform of function:
>
> t ,0=< t =<1
> g(t)=
> 1.5-0.5t , 1< t =<3
>
> to tell the truth i dont even know how to make Mathematica print that
> function.
>
> Regards,
> DJKapi
>
>
>
Bob Hanlon
Chantilly, VA