Re: power series in more than one variables
- To: mathgroup at smc.vnet.net
- Subject: [mg55713] Re: [mg55679] power series in more than one variables
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Mon, 4 Apr 2005 00:59:18 -0400 (EDT)
- Reply-to: hanlonr at cox.net
- Sender: owner-wri-mathgroup at wolfram.com
Clear[mySeries];
mySeries[func_, var:{__Symbol},n_Integer]:=
Plus@@(Cases[Expand@Normal@
Series[func/.Thread[var->h*var],
Sequence@@Thread[{var,0,n}]],_*h^n]/.h->1);
mySeries[f[x,y,z],{x,y,z},2]
(1/2)*Derivative[2, 0, 0][f][0, 0, 0]*x^2 + z*Derivative[1, 0, 1][f][0, 0, 0]*x +
y*Derivative[1, 1, 0][f][0, 0, 0]*x +
(1/2)*z^2*Derivative[0, 0, 2][f][0, 0, 0] + y*z*Derivative[0, 1, 1][f][0, 0, 0] +
(1/2)*y^2*Derivative[0, 2, 0][f][0, 0, 0]
Bob Hanlon
>
> From: "Christoph Lhotka" <lhotka at astro.univie.ac.at>
To: mathgroup at smc.vnet.net
> Date: 2005/04/03 Sun AM 05:50:48 EDT
> To: mathgroup at smc.vnet.net
> Subject: [mg55713] [mg55679] power series in more than one variables
>
> Hello !
>
> How can I define a power series in Mathematica with more than more
variables
> (x,y,z,...), where only terms x^k*y^l*z^m*..., where k+l+m+...=N should
be
> considered? I havwe tried Series[exp,{x,..},{y,...},...] but this only returns
> nested taylor series. My usual approach is to define an artificial
> perturbation parameter, say lambda^k+l+m, holding terms of equal
powers
> together, but this is not satisfying when only dealing with numerical series,
> where the coefficients should only be numeric not mixed symbolic (defining
it
> this way will give you as third argument to SeriesData non numerical
entries.
>
> Does anyone have some sugestions?
>
> -- Christoph Lhotka --
> University of Vienna
> Institute for Astronomy
> Tuerkenschanzstr. 17
> 1180 Vienna, Austria
> mail. lhotka at astro.univie.ac.at
>
>