Re: Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- To: mathgroup at smc.vnet.net
- Subject: [mg53968] Re: [mg53937] Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- From: Daniel Lichtblau <danl at wolfram.com>
- Date: Sat, 5 Feb 2005 03:16:29 -0500 (EST)
- References: <200502040912.EAA01094@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
Zak Seidov wrote:
>Dear Math gurus,
>I try to copy Math session:
>\!\(FullSimplify[\[Product]\+\(p = 2\)\%\[Infinity]\((\(p\^2 +
>1\)\/\(p\^2 - \1\))\)]
>n Sinh[\[Pi]]\/\[Pi]\),
>that is,
> Product {for p=2 to infinity} (p^2+1)/(p^2-1)=>
>sinh(pi)/pi=3.67608 -
>is it OK,
>or this should be 3/2?
>Please email me your help:
>seidovzf at yahoo.com
>
>Many thanks,
>Zak
>
>
The result you get is consistent with a numeric approximation e.g. by
taking the product to 10^3.
Alternatively you can try to verify that the sum of logs is correct by
doing an indefinite sum. First we do the sum to infinity and recover the
log of your result.
In[5]:= Sum[Log[(p^2+1)/(p^2-1)], {p,2,Infinity}]
Out[5]= Log[2] - LogGamma[2 - I] - LogGamma[2 + I]
Fine so far. Now we do the indefinite summation, that is, sum to
arbitrary 'n'.
In[8]:= f[n_] = Sum[Log[p^2+1]-Log[p^2-1], {p,2,n}]
Out[8]= Log[2] - Log[Gamma[n]] + Log[Gamma[(1 - I) + n]] +
Log[Gamma[(1 + I) + n]] - Log[Gamma[2 + n]] - LogGamma[2 - I] -
LogGamma[2 + I]
We check that this agrees in the limit as n goes to infinity.
In[9]:= InputForm[ff = Limit[f[n], n->Infinity]]
Out[9]//InputForm=
((3*I)*Pi + Log[8] - 3*Log[-Gamma[2 - I]] - 3*Log[Gamma[2 + I]])/3
In[10]:= InputForm[FullSimplify[ff]]
Out[10]//InputForm= Log[Sinh[Pi]/Pi]
Finally one can ask whether the indefinite sum is correct. To show this
you would start with:
In[31]:= InputForm[g[n_] = FullSimplify[f[n]-f[n-1],
Assumptions->{n>2,Element[n,Integers]}]]
Out[31]//InputForm=
-Log[Gamma[-I + n]] - Log[Gamma[I + n]] +
Log[Gamma[(1 - I) + n]/(-1 + n^2)] + Log[Gamma[(1 + I) + n]]
You can now try various methods to confirm that this is your summand.
I'll leave the symbolic proof to others and just show a quick numerical
verification.
In[34]:= FullSimplify[g[5] - (Log[5^2+1] - Log[5^2-1])]
Out[34]= 0
Daniel Lichtblau
Wolfram Research
- Follow-Ups:
- Re: Re: Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- From: DrBob <drbob@bigfoot.com>
- Re: Re: Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- From: Andrzej Kozlowski <akoz@mimuw.edu.pl>
- Re: Re: Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- References:
- Product {for p=2 to infinity} (p^2+1)/(p^2-1)
- From: seidovzf@yahoo.com (Zak Seidov)
- Product {for p=2 to infinity} (p^2+1)/(p^2-1)