Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Solve or Reduce on a monstrosity of an expresssion (and a prize!)

• To: mathgroup at smc.vnet.net
• Subject: [mg57487] Re: Solve or Reduce on a monstrosity of an expresssion (and a prize!)
• From: Maxim <ab_def at prontomail.com>
• Date: Sun, 29 May 2005 01:03:51 -0400 (EDT)
• References: <200505230620.CAA04045@smc.vnet.net> <EEA0FBBD-9C31-419A-8D0B-7C73AE4DA32E@akikoz.net> <Pine.LNX.4.58.0505231817420.9452@boston.eecs.umich.edu> <458D701E-37FA-425F-89C4-52A5628E22CF@akikoz.net> <Pine.LNX.4.58.0505241736010.24188@boston.eecs.umich.edu> <1D91709F-1E4D-4B98-95F5-695F7BD65577@akikoz.net> <Pine.LNX.4.58.0505242049410.3527@boston.eecs.umich.edu> <F016112F-BF6B-4D4E-8A3C-1F38AB3DDC5F@akikoz.net> <Pine.LNX.4.58.0505251303210.3527@boston.eecs.umich.edu> <D20ACE19-9F36-432F-9C52-9D059659BEAA@akikoz.net> <d76ojk$7ru$1@smc.vnet.net>
• Sender: owner-wri-mathgroup at wolfram.com

On Fri, 27 May 2005 09:17:40 +0000 (UTC), Daniel Reeves  
<dreeves at umich.edu> wrote:

> Well, it's for a theorem in my phd thesis about the efficacy of a game
> theory approximation technique in a class of simple auction games.
>
> To open this up to non-Mathematica folks, here's the function (the
> derivative of the original function I posted) in a platform-neutral
> format:
>   http://ai.eecs.umich.edu/people/dreeves/f.txt
>
> Again, the goal is to show that that expression is negative in  
> (0,(n-1)/n)
> for all integers n>=2.  One way to show that is to show that the
> expression has at most 2 roots and show that it is zero at x = (n-1)/n  
> and
> at x = -(n+1)^2/(n*(n-1)).  (It is.)
>

Sometimes we can make it easier for GroebnerBasis if we combine common  
subexpressions; also, with the proper choice of replacements, we can make  
the coefficients integer:

In[1]:=
f[x_, n_] := 9/2/c[x, n]^2*(n + 1)b[x, n]^2 (x - d[x, n])(x - x*d[x, n]  
+ d[x, n] + d[x, n]^2 + n (d[x, n] - 1) (x + d[x, n]))

a[x_, n_] := 9*(n + 1)^2 + Sqrt[3(n + 1)^3 (x^2 (n - 1) + 27(n + 1))];

b[x_, n_] := (a[x, n](n - 1) x^2)^(1/3);

c[x_, n_] := -3^(2/3) x^2 (n^2 - 1) + 3^(1/3)(x^2(n^2 - 1) (9 + 9n  
+ Sqrt[3(n + 1) (x^2(n - 1) + 27(n + 1))]))^(2/3);

d[x_, n_] := c[x, n]/(3 b[x, n] (n + 1));

In[6]:=
D[f[x, n], x] /.
         27*(1 + n) + (-1 + n)*x^2 -> 3*a^2/(1 + n) /.
       (-1 + n^2)*x^2*(9 + 9*n + 3*Sqrt[a^2]) |
           (-1 + n)*x^2*(9*(1 + n)^2 + 3*Sqrt[(1 + n)^2*a^2]) ->
         9*b^3 //
     Refine[#, {n > 0, a > 0, b > 0}]& //
   Together // Numerator // FullSimplify

Out[6]=
4374*a*b^10 - 486*a*b^8*(-1 + n^2)*(a + 12*(1 - b + n))*x - 4374*a*b^8*(-1  
+ n^2)*x^2 - 81*b^5*(-1 + n^2)^2*(b^3 + 2*a^2*(b - 6*(1 + n))  
+ 12*a*(3*b^2 + 2*b*(1 + n) - 3*(1 + n)^2))*x^3 + 1458*a*b^6*(-1  
+ n^2)^2*x^4 + 27*b^3*(-1 + n^2)^3*(12*a^2*(1 + n) + b^2*(6 - b + 6*n)  
+ 18*a*(b^2 + 2*(1 + n)^2))*x^5 - 162*a*b^4*(-1 + n^2)^3*x^6  
+ 18*b^2*(a*(3 + a - 3*b) + 3*b + 3*(a + b)*n)*(-1 + n^2)^4*x^7 + 3*(-1  
+ n^2)^5*(b^2 + 2*a*(3 + a + 3*n))*x^9 + (-1 + n^2)^6*x^11

In[7]:=
GroebnerBasis[
     {%,
      (1 + n)*(27*(1 + n) + (-1 + n)*x^2) - 3*a^2,
      (-1 + n^2)*x^2*(9 + 9*n + 3*a) - 9*b^3},
     {n, x}, {a, b},
     MonomialOrder -> EliminationOrder] //
   Factor // Timing

Out[7]=
{114.312*Second, {(-1 + n)^7*(1 + n)^8*x^13*(1 - n + n*x)*(1 + 2*n + n^2 -  
n*x + n^2*x)*(27 + 27*n - x^2 + n*x^2)}}

In[8]:=
Reduce[%[[2]] == 0 && n > 1, x, Reals]

Out[8]=
n > 1 && (x == (-1 - 2*n - n^2)/(-n + n^2) || x == 0 || x == (-1 + n)/n)

These are all the possible real roots (not necessarily the set of roots of  
D[f[x, n], x] exactly, because of zeros in the denominator; also there  
could be parasite solutions due to the presence of radicals).

Maxim Rytin
m.r at inbox.ru

• Follow-Ups:
  • Re: Re: Solve or Reduce on a monstrosity of an expresssion (and a prize!)
    • From: Andrzej Kozlowski <akoz@mimuw.edu.pl>

• References:
  • Solve or Reduce on a monstrosity of an expresssion (and a prize!)
    • From: Daniel Reeves <dreeves@umich.edu>