       Re: another problem with Infinite Products

• To: mathgroup at smc.vnet.net
• Subject: [mg65522] Re: [mg65481] another problem with Infinite Products
• From: Daniel Lichtblau <danl at wolfram.com>
• Date: Thu, 6 Apr 2006 06:52:12 -0400 (EDT)
• References: <200604051055.GAA21639@smc.vnet.net>
• Sender: owner-wri-mathgroup at wolfram.com

```Roger Bagula wrote:
> Gary Adamson a long time ago came up with a sort of ultra-zeta sum:
> A=Sum[1/n^n,{n,1,Infinity}]=1.291..
> That is very close to  2- Sqrt...
> One wonders if the Product:
> Product[1/(1-1/Prime[n]^Prime[n]),{n,1,Infinity}]-->A
> or is it?
> Product[1/(1-1/Prime[n]^n),{n,1,Infinity}]-->A
> It is clear that both these products should converge
> and I think that the second should be A on reconsideration.
> But Mathematica disagrees:
>
> A = Sum[1/n^n, {n, 1, Infinity}]
> N[%]
> 1.2912859970626636`
> Product[1/(1 - 1/Prime[n]^Prime[n]), {n, 1, Infinity}]
> N[%]
> 1.3850602852044895`
> Product[1/(1-1/Prime[n]^n),{n,1,Infinity}]
> N[%]
> 2.2691047868959395`

I am not sure what is meant in the subject header by the phrase "problem
with Infinite Products". If it refers to this being "another example"
that involves infinite products, well and good. If it means "problem" as
in "bug", well, that would be incorrect.

I should mention, in case it is not already clear, that these products
do not have known closed forms in terms of defined functions. Hence they
return unevaluated. Application of N in Mathematica will invoke NValues
that evaluate them as truncations, possibly with some form of
extrapolation. As will become clear below, at least two of the numeric
evaluations are quite reasonable.

As for the specifics of these examples, it is clear that

Product[1/(1 - 1/Prime[n]^Prime[n]), {n, 1, Infinity}]

will be smaller than

Product[1/(1-1/Prime[n]^n),{n,1,Infinity}]

To see that the former is larger than

n2nrecipsum = Sum[1/n^n, {n, 1, Infinity}]

is fairly straightforward and mostly elementary math. Details are
provided below. We hereafter take for granted that each product
converges though this too is not difficult to prove.

First we define for notation purposes

pnpn[n_] := 1/Prime[n]^Prime[n]

Then our product may be written

pp = Product[1/(1-pnpn[n]),{n,1,Infinity}]

Since all factors are positive we know it is the exponential of its
logarithm, so we work with

logpp = Sum[Log[1/(1-pnpn[n])], {n,1,Infinity}]

Since pnpn[n]<1 we can expand each log as an infinite sum about zero,
obtaining

logpp = Sum[Sum[pnpn[n]^j/j, {j,1,Infinity}],
{n,1,Infinity}]

Here we require some post-calculus math: as the stars are properly
aligned we can switch the order of summation, to obtain

logpp = Sum[Sum[pnpn[n]^j/j, {n,1,Infinity}], {j,1,Infinity}]

We still cannot sum this explicitly, but we can minorize it by
truncation, and the truncated versions can be summed.

logppreduced[m_] := Sum[Sum[pnpn[n]^j/j, {n,1,m}],
{j,1,Infinity}]
ppreduced[m_] := Exp[logppreduced[m]]

Note that these are increasing functions of m. If we find some that are
larger than n2nrecipsum then we can conclude the original product is larger.

In:= InputForm[ppapproxtable10 =
Table[ppreduced[m], {m,1,10}]]

Out//InputForm=
{4/3, 18/13, 28125/20306, 7720715625/5574281284,
40051095877840018125/28916500101601742968,
311037947003521544297171294989375/
224566360270448556138245899597024,
257303112735781697706873542424979340522046371095619375/
185770334680987315271766907548466081748690434519412224,
5090535356990520743958828490802637081255368479042693424799727037262506694931\
25/36753168157146013578531065523610752369996787371198452775938443849075962470\
7072,
96629782385213577755527315475090745315830719668036862913363713717694372\
3539154430934663228123511502122395625/697657592362105993889141526695312334515\
430396279207005661133480952594500728389800754298187596407056120338432,
1222241153761054248281966261025369409274584690758326302779868638284392065563\
8089259422255118350077241514349839708995048550866095718050049489956849375/882\
44617712116664750138910377647286194885591081164810294385639757572231217489133\
02294604250917317541588237740724590755567562424488347610728779374592}

Furthermore N[ppapproxtable10,50] will reveal that these have stabilized
to over 40 decimal places, the first several digits being 1.3850602852...

Now we'll have a look at n2nrecipsum.

Aside remark: n2nrecipsum is reasonably close to 2-1/Sqrt (I assume
this is what was meant above). They agree to between three and four
decimal places. It is well known though not elementary (follows from
Liouville's theorem, the one on diophantine approximation by rationals,
not the one that bounded entire functions are constant) that n2nrecipsum
is transcendental. I believe it then follows that it will not be too
well approximated by an algebraic of low degree and involving smallish
coefficients in its minimal polynomial. I guess I'm being sufficiently
vague here that I can assert the veracity, if necessary defining "well
approximated" in such a way as to discard any counterexamples that might
be proferred.

On to the issue at hand. We now observe that it is easy to majorize
n2nrecipsum. We can sum to a finite bound m, then replace n^n by n^m
thereafter in summing from m+1 to infinity. With this we obtain a
sequence of approximations, each element of which is explicitly
evaluatable. It is not hard to show that the sequence converges to
n2nrecipsum. If we learn that any element of that sequence is less than
any ppreduced[j] then we have established that n2nrecipsum<pp.

n2nrecipsumenlarged[m_] := Sum[1/n^n, {n,1,m}] +
Sum[1/n^m, {n,m+1,Infinity}]

InputForm[n2nrecipsumapproxtable10 =
Table[n2nrecipsumenlarged[m], {m,2,10}]]

Out//InputForm=
{5/4 + (-15 + 2*Pi^2)/12, 139/108 + (-251 + 216*Zeta)/216,
8923/6912 + (-111845 + 1152*Pi^4)/103680,
27891287/21600000 + (-806108207 + 777600000*Zeta)/777600000,
753077249/583200000 + (-332250636263 + 345600000*Pi^6)/326592000000,
620192080073207/480290277600000 +
(-774879868932307123 + 768464444160000000*Zeta)/768464444160000000,
40644910035811590827/31476303632793600000 +
(-248886558707571775009601 + 26230253027328000000*Pi^8)/
247875891108249600000000,
21600371677519118879091707/16727798278915463577600000 +
(-4106541588424891370931874221019 + 4098310578334288576512000000000*
Zeta)/4098310578334288576512000000000,
67501161497474683459322666743/52274369621610823680000000000 +
(-4548726323970653923866830952038699 +
48572569817295272017920000000*Pi^10)/
4544206769257059173636505600000000}

N[n2nrecipsumapproxtable10,20] reveals these have converged to around 8
digits, to 1.291286 or so. As 1.2913<1.385 we have are now quite certain
that n2nrecipsum<pp. Along the way we have validated the approximate
values for these that were given in the original note.

Daniel Lichtblau
Wolfram Research

```

• Prev by Date: Re: Lost Values after For[ ] loop
• Next by Date: Pointsize in MultipleListPlot
• Previous by thread: another problem with Infinite Products
• Next by thread: Re: another problem with Infinite Products