Mathematica 9 is now available
Services & Resources / Wolfram Forums
-----
 /
MathGroup Archive
2006
*January
*February
*March
*April
*May
*June
*July
*August
*September
*October
*November
*December
*Archive Index
*Ask about this page
*Print this page
*Give us feedback
*Sign up for the Wolfram Insider

MathGroup Archive 2006

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Symmetric polynomials

  • To: mathgroup at smc.vnet.net
  • Subject: [mg69012] Re: [mg68940] Symmetric polynomials
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Sat, 26 Aug 2006 02:05:00 -0400 (EDT)
  • Sender: owner-wri-mathgroup at wolfram.com

Needs["Algebra`SymmetricPolynomials`"];

P=y1^2 y2 y3+y1 y2^2 y3+y1 y2 y3^2+
      y1^2 y2 y4+y1 y2^2 y4+y1^2 y3 y4+
      y2^2 y3 y4+y1 y3^2 y4+y2 y3^2 y4+
      y1 y2 y4^2+y1 y3 y4^2+y2 y3 y4^2;

var=Union[Cases[P,_Symbol,Infinity]]

{y1,y2,y3,y4}

s=Table[ToExpression["s"<>ToString[n]],{n,Length[var]}]

{s1,s2,s3,s4}

ps=SymmetricReduction[P,var,s][[1]]

s1 s3-4 s4

S=Table[ToExpression["S"<>ToString[n]],{n,Length[var]}]

{S1,S2,S3,S4}

eqns=Thread[S==(
        SymmetricReduction[#,var,s][[1]]&/@
          Table[Total[var^n],{n,4}])]

{S1 == s1, S2 == s1^2 - 2*s2, S3 == s1^3 - 3*s2*s1 + 3*s3, 
  S4 == s1^4 - 4*s2*s1^2 + 4*s3*s1 + 2*s2^2 - 4*s4}

Simplify[ps/.Solve[eqns,s][[1]]]

(S2*S1^2)/2 - S3*S1 - S2^2/2 + S4

Simplify[P==(%/.Thread[S->Table[Total[var^n],{n,4}]])]

True


Bob Hanlon

---- shubi at nusun.jinr.ru wrote: 
> Dear All,
> 
>    Is the possibility in "Mathematica" express symmetric functions, for
> example:
> 
> P=y1^2 y2 y3 + y1 y2^2 y3 + y1 y2 y3^2 + y1^2 y2 y4 +
> y1 y2^2 y4 + y1^2 y3 y4 + y2^2 y3 y4 + y1 y3^2 y4 +
> y2 y3^2 y4 + y1 y2 y4^2 + y1 y3 y4^2 + y2 y3 y4^2;
> 
> by the standard symmetric polynomials:
> S1=y1+y2+y3+y4;
> S2=y1^2+y2^2+y3^2+y4^2;
> S3=y1^3+y2^3+y3^3+y4^3;
>       . . .
> 
> Best regards
>                       Nodar Shubitidze
>                       Joint Institute for Nuclear Research
>                       Dubna, Moscow region, Russia
> 


  • Prev by Date: RE: Change of Basis function
  • Next by Date: Graphics--If condition in Plot3D?????????
  • Previous by thread: Re: Symmetric polynomials
  • Next by thread: Change of Basis function