Re: principal value
- To: mathgroup at smc.vnet.net
- Subject: [mg67927] Re: principal value
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Fri, 14 Jul 2006 02:11:33 -0400 (EDT)
- Organization: The University of Western Australia
- References: <e95aqh$gin$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
In article <e95aqh$gin$1 at smc.vnet.net>, dimmechan at yahoo.com wrote:
> I have to evaluate the following integral (from an elasticity project)
[For clarity, I have converted the input and output expressions to
InputForm]
Integrate[ArcTan[x]/(x - p), {p, 0, 1}, {x, 0, 1}]
> Since p take values in the interval {0,1}, the option PrincipalValue
> must be used.
Integrate[ArcTan[x]/(x - p), {p, 0, 1}, {x, 0, 1},
PrincipalValue -> True]
(1/32) (32 Catalan + 4 Log[2]^2 - Pi (Pi + Log[16]))
with numerical value
N[%]
0.39539882209500143
> I want also to compute previous numerically.
So why not use NIntegrate? The syntax
NIntegrate[f[x], {x, 0, p, 1}]
tests for a singularity at the intermediate point. So try
NIntegrate[ArcTan[x]/(x - p), {p, 0, 1}, {x, 0, p, 1}]
However, this does not work: NIntegrate gives a message to the effect
that its singularity handling has failed.
Next, try splitting the integration into two parts:
eps = 10^(-5);
NIntegrate[ArcTan[x]/(x - p), {p, 0, 1}, {x, 0, p - eps}] +
NIntegrate[ArcTan[x]/(x - p), {p, 0, 1}, {x, p + eps, 1}]
0.39538307925436555
which is a reasonable approximation; it can be shown that the error is
first order in eps:
-Pi/2 eps
For this 2D integral you can combine Integrate and NIntegrate as
follows: first compute the singular integral using Integrate,
Assuming[0 < x < 1,
Integrate[1/(x - p), {p, 0, 1}, PrincipalValue -> True]]
Log[-(x/(-1 + x))]
then perform the second integration using NIntegrate:
NIntegrate[ArcTan[x] Log[x/(1 - x)], {x, 0, 1}]
0.39539882209498356
This "trick" is quite general for singular integrals.
Cheers,
Paul
_______________________________________________________________________
Paul Abbott Phone: 61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
AUSTRALIA http://physics.uwa.edu.au/~paul