MathGroup Archive 2007

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: "hard" simplification

  • To: mathgroup at smc.vnet.net
  • Subject: [mg75356] Re: [mg75315] "hard" simplification
  • From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
  • Date: Thu, 26 Apr 2007 03:33:50 -0400 (EDT)
  • References: <200704250931.FAA26921@smc.vnet.net> <3D50FE62-46D7-4053-A78F-D7EBA1093C11@mimuw.edu.pl>

On 25 Apr 2007, at 21:28, Andrzej Kozlowski wrote:

>
> On 25 Apr 2007, at 18:31, dimitris wrote:
>
>> Hello.
>>
>> I have two expressions. (where a>1)
>>
>> In[56]:=
>> o1 = (1/(16*(-1 + a^2)^(3/2)))*((3*(Sqrt[a - Sqrt[-1 + a^2]] - Sqrt[a
>> + Sqrt[-1 + a^2]]) +
>>       a^2*(-Sqrt[a - Sqrt[-1 + a^2]] + Sqrt[a + Sqrt[-1 + a^2]]) +
>> a*(Sqrt[(-(-1 + a^2))*(-a + Sqrt[-1 + a^2])] +
>>         Sqrt[(-1 + a^2)*(a + Sqrt[-1 + a^2])]))*Pi);
>>
>> In[58]:=
>> o2 = ((2*a + 3)*Pi)/(2^(7/2)*(a + 1)^(3/2));
>>
>> These expressions are equal. (They came from the evaluation of the
>> same integral; first by hand, second
>> by Mathematica).
>>
>> (If somebody is interested the integral is
>>
>> In[61]:=
>> Integrate[1/(x^4 + 2*a*x^2 + 1)^2, {x, 0, Infinity}, Assumptions -> a
>>> 1]
>>
>> Out[61]=
>> ((3*(Sqrt[a - Sqrt[-1 + a^2]] - Sqrt[a + Sqrt[-1 + a^2]]) + a^2*(-
>> Sqrt[a - Sqrt[-1 + a^2]] + Sqrt[a + Sqrt[-1 + a^2]]) +
>>     a*(Sqrt[(-(-1 + a^2))*(-a + Sqrt[-1 + a^2])] + Sqrt[(-1 + a^2)*(a
>> + Sqrt[-1 + a^2])]))*Pi)/(16*(-1 + a^2)^(3/2))
>>
>> and the simpler expression can be found by
>>
>> In[65]:=
>> (1/(x^4 + 2*a*x^2 + 1)^2)*Dt[x] /. x -> Sqrt[y]
>> Integrate[% /. Dt[y] -> 1, {y, 0, Infinity}, Assumptions -> a > 1]
>>
>> Out[65]=
>> Dt[y]/(2*Sqrt[y]*(1 + 2*a*y + y^2)^2)
>>
>> Out[66]=
>> ((3 + 2*a)*Pi)/(8*Sqrt[2]*(1 + a)^(3/2))
>>
>> )
>>
>> Indeed
>>
>> In[84]:=
>> ({#1, RootReduce[Simplify[o /. a -> #1]]} & ) /@ Table[Random 
>> [Integer,
>> {2, 100}], {20}]
>>
>> Out[84]=
>> {{100, 0}, {54, 0}, {74, 0}, {63, 0}, {96, 0}, {44, 0}, {46, 0}, {26,
>> 0}, {80, 0}, {14, 0}, {23, 0}, {46, 0}, {3, 0}, {64, 0},
>>   {70, 0}, {59, 0}, {71, 0}, {17, 0}, {23, 0}, {56, 0}}
>>
>> 1) Can somebody show me one workaround (in a CAS!) in order to show
>> that these expressions are indeed equal?
>>
>> 2) In the same vein with Vladimir's posts (and stealing his
>> trademark!) can someone show me a workaround
>> that will simplify expression o1 to its equivalent (for a>1) o2?
>>
>> Thanks in advance!
>>
>> Dimitris
>>
>>
>
>
> I will only do (1) since I am in principle opposed to misusing CAS  
> for the purpose (2) (and perhaps also because I can't do it ;-)).
>
> First, we start with the definitions:
>
>
> o1 = (1/(16*(-1 + a^2)^(3/2)))*
>     ((3*(Sqrt[a - Sqrt[-1 + a^2]] -
>         Sqrt[a + Sqrt[-1 + a^2]]) +
>       a^2*(-Sqrt[a - Sqrt[-1 + a^2]] +
>         Sqrt[a + Sqrt[-1 + a^2]]) +
>       a*(Sqrt[(-(-1 + a^2))*(-a + Sqrt[-1 + a^2])] +
>         Sqrt[(-1 + a^2)*(a + Sqrt[-1 + a^2])]))*Pi);
>
> o2 = ((2*a + 3)*Pi)/(2^(7/2)*(a + 1)^(3/2));
>
> We now substitute 1+t^2 for a^2 (O.K. since a>1):
>
> p1 = Simplify[o1 /. a^2 -> 1 + t^2, t > 0];
>
> Next, we substitute c^2 for a-t and d^2 for a+t, where c and d are >0:
>
>
> p2 = Simplify[p1 /. {a - t -> c^2, a + t -> d^2},
>    {c > 0, d > 0}]
>
>
> (Pi*(c*(-t^2 + a*t + 2) + d*(t^2 + a*t - 2)))/(16*t^3)
>
> Now we use GroebnerBasis to eliminate t,c, and d:
>
>
> sol = GroebnerBasis[{V - p2, a^2 - (1 + t^2),
>     a - t - c^2, a + t - d^2}, {V, a}, {t, c, d}]
>
>
> {-16384*V^4*a^6 + 1024*Pi^2*V^2*a^5 + 49152*V^4*a^4 -
>    16*Pi^4*a^4 - 3840*Pi^2*V^2*a^3 - 49152*V^4*a^2 +
>    72*Pi^4*a^2 + 3840*Pi^2*V^2*a + 16384*V^4 - 81*Pi^4}
>
> Finally we solve for V and FullSimlify:
>
> FullSimplify[Solve[sol[[1]] == 0, V], a > 1]
>
>
> {{V -> -(((2*a + 3)*Pi)/(8*Sqrt[2]*(a + 1)^(3/2)))},
>   {V -> ((2*a + 3)*Pi)/(8*Sqrt[2]*(a + 1)^(3/2))},
>   {V -> -((Pi*Abs[3 - 2*a])/(8*Sqrt[2]*(a - 1)^(3/2)))},
>   {V -> (Pi*Abs[3 - 2*a])/(8*Sqrt[2]*(a - 1)^(3/2))}}
>
>
> It's clear that only the second answer satisfies the conditions of  
> the problem.
>
> Of course this required some "hand steering" of Mathematica. I will  
> be surprised if someone shows that this coudl be done " on autmatic  
> pilot'.
>
> Andrzej Kozlowski
>
>

I just noticed that the above argument does not constitute a strictly  
rigorous mathematical proof due to the substitution
a-t->c^2, where c>0, which of course need not always hold. However,  
in the cases when it does not hold one can use the substitution
a-t->-c^2, where c>0 and obtain the same solution for V.

Andrzej Kozlowski



  • Prev by Date: Re: "hard" simplification
  • Next by Date: Re: minmum of a function
  • Previous by thread: Re: "hard" simplification
  • Next by thread: Porting waveforms out of Mathematica and into a D/A converter