Re: Foucault pendulum
- To: mathgroup at smc.vnet.net
- Subject: [mg80147] Re: Foucault pendulum
- From: Jens-Peer Kuska <kuska at informatik.uni-leipzig.de>
- Date: Tue, 14 Aug 2007 06:49:19 -0400 (EDT)
- Organization: Uni Leipzig
- References: <f9mq8f$r63$1@smc.vnet.net> <f9p4db$qdh$1@smc.vnet.net>
- Reply-to: kuska at informatik.uni-leipzig.de
Hi,
sorry the last version has a bug
here is a nicer version
pendelPos[{x_, y_}] := {x, y, -Sqrt[10 - x^2 - y^2]}
pendel[tau_?NumericQ,
sol_] := ({AbsoluteThickness[3],
Line[{{0, 0, 0}, pendelPos[{x[t], y[t]}]}],
Sphere[pendelPos[{x[t], y[t]}], 0.15]} /. sol[[1]]) /. t -> tau
Manipulate[
DynamicModule[{traj, sol, fed, fulltraj},
fde =
{x''[t] == -\[Omega]^2*x[t] +
2 \[CapitalOmega]*Sin[\[Phi]]*y'[t] ,
y''[t] == -\[Omega]^2*y[t] -
2 \[CapitalOmega]*Sin[\[Phi]]*x'[t]};
sol = NDSolve[
Join[fde, {x[0] == 2, y[0] == 2, x'[0] == 0, y'[0] == 0}],
{x[t], y[t]}, {t, 0, 64 Pi}, MaxSteps -> Infinity];
fulltraj = ParametricPlot3D[
{x[t], y[t], -4} /. sol[[1]], {t, 0, 64 Pi},
PlotPoints -> 1024
];
traj = ParametricPlot3D[
pendelPos[{x[t], y[t]} /. sol[[1]]], {t, t1, t1 + 4 Pi},
PlotStyle -> RGBColor[1, 0, 0]
];
Graphics3D[
{traj[[1]], fulltraj[[1]], pendel[t1, sol]},
PlotRange -> {{-2.5, 2.5}, {-2.5, 2.5}, {-4, 0}}
]], {{\[Omega], 1, "Pendel Frequence"}, 0.1,
10}, {{\[CapitalOmega], 1/16, "Earth Circum Frequence"}, 0,
1/2}, {{\[Phi], Pi/3, "Latitude"}, 0, Pi/2}, {{t1, 0, "time"}, 0,
60 Pi}
]
Regards
Jens
dimitris wrote:
> On 12 , 14:17, dimitris <dimmec... at yahoo.com> wrote:
>> Hello.
>> Does anyone have notebooks
>> demonstrating Foucault's pendulum?
>>
>> Thanks
>> Dimitris
>
> I mean the motion of a Foucalt's pendulum of course.
>
> Dimitris
>
>